Checkboxes プロパティ

LANSA

Checkboxes プロパティ

Checkboxesプロパティを使用して、このカラムにある全ての項目のチェックボックスの表示のオン・オフを切り替えます。

項目のCheckboxesを使って、個別の項目のチェックボックスの表示を制御することもできます。

次のサンプル・アプリケーションをコピー・貼り付けして、ツリー・ビューのカラムや項目のチェックボックスをどのように指定できるかを確認できます。

Function Options(*DIRECT)

Begin_Com Role(*EXTENDS #PRIM_FORM) Caption('Check Box Tester') Clientheight(585) Clientwidth(413) Height(619) Left(300) Top(108) Width(421)

* Tree & Column Definition

Define_Com Class(#PRIM_TRVW) Name(#TREE) Displayposition(4) Height(241) Left(8) Parent(#COM_OWNER) Tabposition(4) Top(64) Width(393)

Define_Com Class(#PRIM_TVCL) Name(#COL1) Displayposition(1) Image(#VI_DEPTCL) Imageexpanded(#VI_DEPTOP) Keyposition(1) Level(1) Parent(#TREE) Sortposition(1) Source(#DEPTMENT)

Define_Com Class(#PRIM_TVCL) Name(#COL2) Displayposition(1) Image(#VI_SECTCL) Imageexpanded(#VI_SECTOP) Keyposition(1) Level(2) Parent(#TREE) Sortposition(1) Source(#SECTION)

Define_Com Class(#PRIM_TVCL) Name(#COL3) Displayposition(1) Image(#VI_EMPLOY) Keyposition(1) Level(3) Parent(#TREE) Sortposition(1) Source(#EMPNO)

* Tracing Definition

Define_Com Class(#PRIM_PHBN) Name(#CLEAR) Buttondefault(True) Caption('Clear') Displayposition(2) Left(8) Parent(#COM_OWNER) Tabposition(3) Top(4) Width(393)

Define_Com Class(#PRIM_PHBN) Name(#LOAD) Caption('Load') Displayposition(1) Left(8) Parent(#COM_OWNER) Tabposition(2) Top(32) Width(393)

* Sheet & Page Definition

Define_Com Class(#PRIM_TAB) Name(#SHEET) Displayposition(3) Height(265) Left(8) Parent(#COM_OWNER) Tabposition(1) Top(312) Width(393)

Define_Com Class(#PRIM_TBSH) Name(#PAGE_COL) Caption('Columns') Displayposition(1) Height(239) Left(4) Parent(#SHEET) Tabposition(1) Tabstop(False) Top(22) Width(385)

* Columns Tab

Define_Com Class(#PRIM_GPBX) Name(#GPBX_DEPT) Caption('Department') Displayposition(3) Height(58) Left(8) Parent(#PAGE_COL) Tabposition(3) Tabstop(False) Top(32) Width(361)

Define_Com Class(#PRIM_GPBX) Name(#GPBX_SECT) Caption('Section') Displayposition(2) Height(58) Left(8) Parent(#PAGE_COL) Tabposition(2) Tabstop(False) Top(96) Width(361)

Define_Com Class(#PRIM_GPBX) Name(#GPBX_EMPNO) Caption('Employee') Displayposition(1) Height(58) Left(8) Parent(#PAGE_COL) Tabposition(1) Tabstop(False) Top(160) Width(361)

Define_Com Class(#PRIM_CKBX) Name(#CKBX_DEPT_CHK) Caption('Check boxes') Displayposition(1) Left(16) Parent(#GPBX_DEPT) Tabposition(1) Top(16) Width(89)

Define_Com Class(#PRIM_CKBX) Name(#CKBX_SECT_CHK) Caption('Check boxes') Displayposition(1) Left(16) Parent(#GPBX_SECT) Tabposition(1) Top(16) Width(97)

Define_Com Class(#PRIM_CKBX) Name(#CKBX_EMPNO_CHK) Caption('Check boxes') Displayposition(1) Left(16) Parent(#GPBX_EMPNO) Tabposition(1) Top(16) Width(97)

* Items Tab

Define_Com Class(#PRIM_TBSH) Name(#PAGE_ITEMS) Caption('Items') Displayposition(2) Height(239) Left(4) Parent(#SHEET) Tabposition(2) Tabstop(False) Top(22) Width(385)

Define_Com Class(#PRIM_CKBX) Name(#CKBX_ITEM_CHECKBOX) Caption('Check boxes') Displayposition(3) Left(16) Parent(#PAGE_ITEMS) Tabposition(3) Top(32) Width(97)

Define_Com Class(#PRIM_CKBX) Name(#CKBX_ITEM_CHECKED) Caption('Checked') Displayposition(2) Left(16) Parent(#PAGE_ITEMS) Tabposition(2) Top(56) Width(97)

Define_Com Class(#PRIM_CKBX) Name(#CKBX_ITEM_CHKENABLED) Caption('Check box enabled') Displayposition(1) Left(16) Parent(#PAGE_ITEMS) Tabposition(1) Top(80) Width(201)

Define_Com Class(#PRIM_LABL) Name(#LABL_1) Caption('Clear and reload the tree to set check boxes for columns.') Displayposition(4) Height(15) Left(8) Parent(#PAGE_COL) Tabposition(4) Tabstop(False) Top(8) Width(361)

Define_Com Class(#PRIM_LABL) Name(#LABL_2) Caption('Set check box options for individual items in the tree.') Displayposition(4) Height(15) Left(16) Parent(#PAGE_ITEMS) Tabposition(4) Tabstop(False) Top(16) Width(329)

Evtroutine Handling(#CLEAR.Click)

Clr_List Named(#TREE)

Endroutine

Evtroutine Handling(#LOAD.Click)

* Load the Tree View

Select Fields(#TREE) From_File(PSLMST)

Add_Entry To_List(#TREE)

Endselect

Endroutine

* ===========================================================================================

*

* Form Initialization

*

* ===========================================================================================

Evtroutine Handling(#com_owner.CreateInstance)

Set Com(#com_owner) Caption(*component_desc)

* Load the Tree View

Select Fields(#TREE) From_File(PSLMST)

Add_Entry To_List(#TREE)

Endselect

Endroutine

* ===========================================================================================

*

* Handlers

*

* ===========================================================================================

Evtroutine Handling(#CKBX_DEPT_CHK.Click)

If Cond('#CKBX_DEPT_CHK.buttonstate = Checked')

Set Com(#COL1) Checkboxes(True)

Else

Set Com(#COL1) Checkboxes(False)

Endif

Endroutine

Evtroutine Handling(#CKBX_SECT_CHK.Click)

If Cond('#CKBX_SECT_CHK.buttonstate = Checked')

Set Com(#COL2) Checkboxes(True)

Else

Set Com(#COL2) Checkboxes(False)

Endif

Endroutine

Evtroutine Handling(#CKBX_EMPNO_CHK.Click)

If Cond('#CKBX_EMPNO_CHK.buttonstate = Checked')

Set Com(#COL3) Checkboxes(True)

Else

Set Com(#COL3) Checkboxes(False)

Endif

Endroutine

Evtroutine Handling(#CKBX_ITEM_CHECKBOX.Click)

If_Ref Com(#TREE.CurrentItem) Is_Not(*NULL)

If Cond('#CKBX_ITEM_CHECKBOX.buttonstate = Checked')

Set Com(#TREE.currentitem) Checkboxes(True)

Else

Set Com(#TREE.CURRENTITEM) Checkboxes(False)

Endif

Endif

Endroutine

Evtroutine Handling(#CKBX_ITEM_CHKENABLED.Click)

If_Ref Com(#TREE.CurrentItem) Is_Not(*NULL)

If Cond('#CKBX_ITEM_CHKENABLED.buttonstate = Checked')

Set Com(#TREE.currentitem) Checkenabled(True)

Else

Set Com(#TREE.CURRENTITEM) Checkenabled(False)

Endif

Endif

Endroutine

Evtroutine Handling(#CKBX_ITEM_CHECKED.Click)

If_Ref Com(#TREE.CurrentItem) Is_Not(*NULL)

If Cond('#CKBX_ITEM_CHECKED.buttonstate = Checked')

Set Com(#TREE.currentitem) Checked(True)

Else

Set Com(#TREE.CURRENTITEM) Checked(False)

Endif

Endif

Endroutine

End_Com