GroundTrackPlot

Behavior when using GroundTrackPlot Resource & Toggle Command

The GroundTrackPlot resource draws the longitude and latitude time-history of a spacecraft at each propagation step of the entire mission duration. If you want to report data to a GroundTrackPlot at specific points in your mission, then a Toggle On/Off command can be inserted into the mission sequence to control when the GroundTrackPlot is to draw data. When Toggle Off command is issued for a GroundTrackPlot, no ground track data is drawn until a Toggle On command is issued. Similarly when a Toggle On command is used, ground track data is drawn at each integration step until a Toggle Off command is used.

Below is an example script snippet that shows how to use Toggle Off and Toggle On command while using the GroundTrackPlot resource. GroundTrackPlot is turned off for the first 2 days of the propagation:

          Create Spacecraft aSat
Create Propagator aProp

Create GroundTrackPlot aGroundTrackPlot
aGroundTrackPlot.Add = {aSat}

BeginMissionSequence

Toggle aGroundTrackPlot Off
Propagate aProp(aSat) {aSat.ElapsedDays = 2}
Toggle aGroundTrackPlot On
Propagate aProp(aSat) {aSat.ElapsedDays = 4}
        

Behavior when Plotting Data in Iterative Processes

GMAT allows you to specify how data is plotted onto a plot during iterative processes such as differential correction or optimization. The SolverIterations field of GroundTrackPlot resource supports 3 options which are described in the table below:

Behavior when Plotting Longitude and Latitude time-history of a Spacecraft

GMAT’s GroundTrackPlot resource allows you to draw longitude and latitude time-history of a spacecraft. You can choose to draw ground track plot of multiple spacecrafts onto a single texture map of a central body.

Behavior When Specifying Empty Brackets in GroundTrackPlot's Add Field

When using GroundTrackPlot.Add field, if brackets are not populated with user-defined spacecrafts, then GMAT turns off GroundTrackPlot resource and no plot is generated. If you run the script with Add field having empty brackets, then GMAT throws in a warning message in the Message Window indicating that GroundTrackPlot resource will be turned off since no SpacePoints were added to the plot. Below is a sample script snippet that generates such a warning message:

          Create Spacecraft aSat aSat2
Create Propagator aProp
Create GroundTrackPlot aGroundTrackPlot

aGroundTrackPlot.Add = {}

BeginMissionSequence;
Propagate aProp(aSat, aSat2) {aSat.ElapsedDays = 1}
        

This example shows how to use GroundTrackPlot resource. A single spacecraft and a ground station is added to the GroundTrackPlot. Spacecraft’s ground track is plotted for one day of propagation:

          Create Spacecraft aSat
Create Propagator aProp

Create GroundStation aGroundStation

Create GroundTrackPlot aGroundTrackPlot
aGroundTrackPlot.Add = {aSat, aGroundStation}

BeginMissionSequence

Propagate aProp(aSat) {aSat.ElapsedDays = 1}
        

Propagate a spacecraft for two days around a non-default central body. Spacecraft’s ground track is plotted on planet Mars:

          Create Spacecraft aSat
aSat.CoordinateSystem = MarsJ2000Eq
aSat.SMA = 8000
aSat.ECC = 0.0003

Create ForceModel aFM
aFM.CentralBody = Mars
aFM.PointMasses = {Mars}

Create Propagator aProp
aProp.FM = aFM

Create CoordinateSystem MarsJ2000Eq
MarsJ2000Eq.Origin = Mars
MarsJ2000Eq.Axes = MJ2000Eq

Create GroundTrackPlot aGroundTrackPlot
aGroundTrackPlot.Add = {aSat}
aGroundTrackPlot.CentralBody = Mars

BeginMissionSequence

Propagate aProp(aSat) {aSat.ElapsedDays = 2}