SI

Renvoie une certaine valeur si une condition que vous spécifiez est évaluée à VRAI, et une autre valeur si elle est évaluée à FAUX.

Utilisez SI pour effectuer des tests conditionnels sur des valeurs et des formules.

Syntaxe

SI(test_logique;valeur_si_vrai;valeur_si_faux)

test_logique   est toute valeur ou expression qui peut être évaluée à VRAI ou à FAUX. Par exemple, [Trimestre1]=100 est une expression logique ; si la valeur dans une ligne de la colonne [Trimestre1] est égale à 100, l'expression est évaluée à VRAI. Sinon, l'expression est évaluée à FAUX. Cet argument peut utiliser tout opérateur de calcul de comparaison.

valeur_si_vrai   est la valeur qui est renvoyée si test_logique est VRAI. Par exemple, si cet argument est la chaîne de texte « Budgété » et que l'argument test_logique est évalué à VRAI, alors la fonction SI affiche le texte « Budgété ». Si test_logique est VRAI et que valeur_si_vrai est vide, cet argument renvoie 0 (zéro). Pour afficher le mot VRAI, utilisez la valeur logique VRAI pour cet argument. valeur_si_vrai peut être une autre formule.

valeur_si_faux   est la valeur qui est renvoyée si test_logique est évalué à FAUX. Par exemple, si cet argument est la chaîne « Hors budget » et que l'argument test_logique est évalué à FAUX, alors la fonction SI affiche le texte « Hors budget ». Si test_logique est FAUX et que valeur_si_faux est omis, (c'est-à-dire s'il n'y a pas de point-virgule après valeur_si_vrai), alors la valeur logique FAUX est renvoyée. Si test_logique est FAUX et que valeur_si_faux est vide (c'est-à-dire si après valeur_si_vrai, il y a un point-virgule suivi par les parenthèses fermantes), alors la valeur 0 (zéro) est renvoyée. valeur_si_faux peut être une autre formule.

Remarques

• Jusqu'à sept fonctions SI peuvent être imbriquées comme arguments valeur_si_vrai et valeur_si_faux pour construire des tests plus élaborés. Voir le dernier des exemples qui suivent.
• Lorsque les arguments valeur_si_vrai et valeur_si_faux sont évalués, SI renvoie la valeur renvoyée par ces instructions.
• Si des arguments de SI sont des matrices, chaque élément de la matrice est évalué lorsque l'instruction SI est traitée.

Exemple 1

Col1	Col2	Col3	dépense	Formule	Description (résultat)
			50	=SI([dépense]<=100;"Budgété";"Hors budget")	Si le nombre est inférieur ou égal à 100, la formule affiche « Budgété ». Sinon, la fonction affiche « Hors budget ». (Budgété)
23	45	89	50	=SI([dépense]=100;SOMME([Col1];[Col2];[Col3]);"")	Si le nombre est 100, les trois valeurs sont additionnées. Sinon, du texte vide est ("") est renvoyé. ()

Exemple 2

dépenses_réelles	dépenses_prévues	Formule	Description (résultat)
1500	900	=SI([dépenses_réelles]>[dépenses_prévues];"Hors budget";"OK")	Vérifie si la première ligne est hors budget (Hors budget)
500	900	=SI([dépenses_réelles]>[dépenses_prévues];"Hors budget";"OK")	Vérifie si la deuxième ligne est hors budget (OK)

Exemple 3

score	Formule	Description (résultat)
45	=SI([score]>89,"A";SI([score]>79;"B"; SI([score]>69;"C";SI([score]>59;"D";"F"))))	Attribue une note d'évaluation sous forme de lettre au premier score (F)
90	=SI([score]>89;"A";SI([score]>79;"B"; SI([score]>69;"C";SI([score]>59;"D";"F"))))	Attribue une note d'évaluation sous forme de lettre au deuxième score (A)
78	=SI([score]>89;"A";SI([score]>79;"B"; SI([score]>69;"C";SI([score]>59;"D";"F"))))	Attribue une note d'évaluation sous forme de lettre au troisième score (C)

Dans l'exemple précédent, la seconde instruction SI est également l'argument valeur_si_faux de la première instruction SI. De la même façon, la troisième instruction SI est l'argument valeur_si_faux de la deuxième instruction SI. Par exemple, si le premier test_logique ([score]>89) est VRAI, « A » est renvoyé. Si le premier test_logique est FAUX, la deuxième instruction SI est évaluée, etc.

Les lettres de notation sont attribuées aux nombres selon les règles suivantes (en supposant que seuls des entiers sont utilisés).

Si score est	l'expression renvoie
supérieur à 89	A
entre 80 et 89	B
entre 70 et 79	C
entre 60 et 69	D
inférieur à 60	F