Exemples de formules courantes

Microsoft Office List 2007

previous page next page

Afficher tout Afficher tout

Exemples de formules courantes

 Remarque   Vous pouvez utiliser les exemples ci-après dans des colonnes calculées. Les exemples qui ne contiennent pas de références à des colonnes peuvent être utilisés pour spécifier la valeur par défaut d'une colonne.

Formules conditionnelles

AfficherVérifier si un nombre est supérieur ou inférieur à un autre nombre

Utilisez la fonction SI pour effectuer cette opération.

Colonne1 Colonne2 Formule Description
15 000 9 000 =Colonne1>Colonne2 Colonne1 est-il supérieur à Colonne2 ? (0ui)
15 000 9 000 =SI(Colonne1<=Colonne2; "Oui"; "Non") Colonne1 est-il inférieur ou égal à Colonne2? (Non)

AfficherRenvoyer une valeur logique après la comparaison du contenu de colonnes

Pour un résultat qui est une valeur logique (0ui ou Non), utilisez les fonctions ET, OU et NON.
Colonne1Colonne2Colonne3FormuleDescription
1598=ET(Colonne1>Colonne2; Colonne1<Colonne3)15 est-il supérieur à 9 et inférieur à 8 ? (Non)
1598=OU(Colonne1>Colonne2; Colonne1<Colonne3)15 est-il supérieur à 9 ou inférieur à 8 ? (Oui)
1598=NON(Colonne1+Colonne2=24)15 plus 9 est-il égal à 24 ? (Non)

Pour un résultat qui est un autre calcul ou pour toute autre valeur que Oui ou Non, utilisez les fonctions SI, ET et OU.

Colonne1Colonne2Colonne3FormuleDescription
1598=SI(Colonne1=15; "Oui"; "Non")Si la valeur de Colonne1 égale 15, alors renvoyer "Oui". (Oui)
1598=SI(ET(Colonne1>Colonne2; Colonne1<Colonne3); "Oui"; "Non")Si 15 est supérieur à 9 et inférieur à 8, alors renvoyer "Oui". (Non)
1598=SI(OU(Colonne1>Colonne2; Colonne1<Colonne3); "Oui"; "Non")Si 15 est supérieur à 9 ou inférieur à 8, alors renvoyer "Oui". (Oui)

AfficherAfficher des zéros sous forme d'espaces blancs ou de tirets

Utilisez la fonction SI pour effectuer cette opération.
Colonne1Colonne2FormuleDescription
1010=Colonne1-Colonne2Second nombre soustrait du premier (0)
1010=SI(Colonne1-Colonne2;"";Colonne1-Colonne2)Renvoie null lorsque la valeur est zéro (colonne vide)
159=SI(Colonne1-Colonne2;"-";Colonne1-Colonne2)Renvoie un tiret lorsque la valeur est zéro (-)

Formules avec le type Date et heure

AfficherAdditionner des dates

Pour ajouter un nombre de jour à une date, utilisez l'opérateur d'addition (+). Notez que lors de la manipulation de dates, le type de la colonne calculée doit être défini à Date et heure.
Colonne1Colonne2FormuleDescription
9/6/20073=Colonne1+Colonne2Ajouter 3 jours à 9/6/2007 (12/6/2007)
10/12/200854=Colonne1+Colonne2Ajouter 54 jours à 10/12/2008 (2/2/2009)

Pour ajouter un nombre de mois à une date, utilisez les fonctions DATE, ANNEE, MOIS et JOUR.

Colonne1Colonne2FormuleDescription
9/6/20073=DATE(ANNEE(Colonne1);MOIS(Colonne1)+Colonne2;JOUR(Colonne1))Ajouter 3 mois à 9/6/2007 (9/9/2007)
10/12/200825=DATE(ANNEE(Colonne1);MOIS(Colonne1)+Colonne2;JOUR(Colonne1))Ajouter 25 mois à 10/12/2008 (10/1/2011)

Pour ajouter un nombre d'années à une date, utilisez les fonctions DATE, ANNEE, MOIS et JOUR.

Colonne1Colonne2FormuleDescription
9/6/20073=DATE(ANNEE(Colonne1)+Colonne2;MOIS(Colonne1);JOUR(Colonne1))Ajoute 3 années à 9/6/2007 (9/6/2010)
10/12/200825=DATE(ANNEE(Colonne1)+Colonne2;MOIS(Colonne1);JOUR(Colonne1))Ajoute 25 années à 10/12/2008 (10/12/2033)

Pour ajouter une combinaison de jours, de mois et d'années à une date, utilisez les fonctions DATE, ANNEE, MOIS et JOUR.

Colonne1FormuleDescription
9/6/2007=DATE(ANNEE(Colonne1)+3;MOIS(Colonne1)+1;JOUR(Colonne1)+5)Ajoute 3 années, 1 mois et 5 jours à 9/6/2007 (14/7/2010)
10/12/2008=DATE(ANNEE(Colonne1)+1;MOIS(Colonne1)+7;JOUR(Colonne1)+5)Ajouter 1 année, 7 mois et 5 jours à 9/6/2007 (14/1/2009)

AfficherCalculer la différence entre deux dates

Utilisez la fonction DATEDIF pour effectuer cette opération.
Colonne1Colonne2FormuleDescription
01-Janv-199515-Juin-1999=DATEDIF(Colonne1; Colonne2;"j")Renvoyer le nombre de jours entre les deux dates (1 626)
01-Janv-199515-Juin-1999=DATEDIF(Colonne1; Colonne2;"am")Renvoyer le nombre de mois entre les dates, en ignorant la partie Années (5)
01-Janv-199515-Juin-1999=DATEDIF(Colonne1; Colonne2;"aj")Renvoyer le nombre de jours entre les dates, en ignorant la partie Années (165)

AfficherCalculer la différence entre deux heures

Pour présenter le résultat au format d'heure standard (heures:minutes:secondes), utilisez l'opérateur de soustraction (-) et la fonction TEXTE.

Pour ce mode calcul, les heures ne doivent pas dépasser 24, et les minutes et les secondes ne doivent pas dépasser 60.

Colonne1Colonne2FormuleDescription
09/06/2007 10:3509/06/2007 15:30=TEXTE(Colonne2-Colonne1;"h")Heures entre deux heures (4)
09/06/2007 10 h 3509/06/2007 15:30=TEXTE(Colonne2-Colonne1;"h:mm")Heures et minutes entre deux heures (4:55)
09/06/2007 10:3509/06/2007 15:30=TEXTE(Colonne2-Colonne1;"h:mm:ss")Heures, minutes et secondes entre deux heures (4:55:00)

Pour présenter le résultat dans un total basé sur une seule unité de temps, utilisez la fonction ENT, ou les fonctions HEURE, MINUTE et SECONDE.

Colonne1Colonne2FormuleDescription
09/06/2007 10:3510/06/2007 15:30=ENT((Colonne2-Colonne1)*24)Nombre total d'heures entre deux heures (28)
09/06/2007 10:3510/06/2007 15:30=ENT((Colonne2-Colonne1)*1440)Nombre total de minutes entre deux heures (1 735)
09/06/2007 10:3510/06/2007 15:30=ENT((Colonne2-Colonne1)*86400)Nombre total de secondes entre deux heures (104 100)
09/06/2007 10:3510/06/2007 15:30=HEURE(Colonne2-Colonne1)Nombre d'heures entre deux heures, lorsque la différence n'excède pas 24. (4)
09/06/2007 10:3510/06/2007 15:30=MINUTE(Colonne2-Colonne1)Nombre de minutes entre deux heures, lorsque la différence n'excède pas 60. (55)
09/06/2007 10:3510/06/2007 15:30=SECONDE(Colonne2-Colonne1)Nombre de secondes entre deux heures, lorsque la différence n'excède pas 60. (0)

AfficherConvertir des heures

Pour convertir des heures au format d'heure standard en nombre décimal, utilisez la fonction ENT.
Colonne1FormuleDescription
10:35=(Colonne1-ENT(Colonne1))*24Nombre d'heures depuis 00:00 (10,583333)
12:15=(Colonne1-ENT(Colonne1))*24Nombre d'heures depuis 00:00 (12,25)

Pour convertir des heures au format décimal en format d'heure standard (heures:minutes:secondes), utilisez l'opérateur de division et la fonction TEXTE.

Colonne1FormuleDescription
10,5833=TEXTE(Colonne1/24; "h:mm")Heures depuis 00:00 (10:35)
12:25=TEXTE(Colonne1/24; "h:mm")Heures depuis 00:00 (12:15)

AfficherInsérer des dates juliennes

L'expression « date julienne » est parfois utilisée pour désigner un format de date qui est une combinaison de l'année en cours et du nombre de jours depuis le début de l'année. Par exemple, le 1er janvier 2007 est représenté par 2007001 et le 31 décembre 2007 est représenté par 2003356.

Il existe également une date julienne couramment utilisée en astronomie, qui est un système de date séquentiel démarrant le 1er janvier 4713 avant J.C.

 Remarque   Ce format n'est pas basé sur le calendrier julien.

Pour convertir une date en date julienne, utilisez les fonctions TEXTE et DATEVAL.

Colonne1FormuleDescription
23/6/2007=TEXTE(Colonne1;"aa")&TEXTE((Colonne1-DATEVAL("1/1/"& TEXTE(Colonne1;"aa"))+1);"000")Date en format julien, avec une année sur deux chiffres (07174)
23/6/2007=TEXTE(Colonne1;"aaaa")&TEXTE((Colonne1-DATEVAL("1/1/"&TEXTE(Colonne1;"aa"))+1);"000")Date en format julien, avec une année sur quatre chiffres (2007174)

Pour convertir une date en date julienne utilisée en astronomie, utilisez la constante 2415018,50.

Cette formule vaut seulement pour les dates postérieures au 1/3/1901 et si vous utilisez le système de date 1900.

Colonne1FormuleDescription
23/6/2007=Colonne1+2415018,50Date au format « Julien », utilisée en astronomie (2454274,50)

AfficherAfficher des dates sous la forme d'un jour de la semaine

Pour convertir des dates en texte indiquant le jour de la semaine, utilisez les fonctions TEXTE et JOURSEM.
Colonne1FormuleDescription
19-Févr-2007=TEXTE(JOURSEM(Colonne1); "jjjj")Calcule le jour de la semaine pour la date et renvoie le nom complet du jour (Lundi)
3-Janv-2008=TEXTE(JOURSEM(Colonne1); "jjj")Calcule le jour de la semaine pour la date et renvoie le nom abrégé du jour (Jeu)

Formules mathématiques

AfficherAdditionner des nombres

Pour additionner des nombres figurant dans deux colonnes ou plus d'une même ligne, utilisez l'opérateur d'addition ou la fonction SOMME.

Colonne1 Colonne2 Colonne3 Formule Description
6 5 4 =Colonne1+Colonne2+Colonne3 Additionne les valeurs des trois premières colonnes (15)
6 5 4 =SOMME(Colonne1;Colonne2;Colonne3) Additionne les valeurs des trois premières colonnes (15)
6 5 4 =SOMME(SI(Colonne1>Colonne2; Colonne1-Colonne2; 10); Colonne3) Si Colonne1 est supérieur à Colonne2, additionner la différence avec Colonne3. Sinon, additionner 10 avec Colonne3. (5)

AfficherSoustraire des nombres

Utilisez l'opérateur de soustraction (-) pour effectuer cette opération.
Colonne1 Colonne2 Colonne3FormuleDescription
15 0009 000-8 000=Colonne1-Colonne2Soustraire 9 000 de 15 000 (6 000)
15 0009 000-8 000=SOMME(Colonne1; Colonne2; Colonne3)Additionner les nombres des trois premières colonnes, y compris les valeurs négatives (16 000)

AfficherCalculer la différence entre deux nombres, exprimée en pourcentage

Utilisez les opérateurs de soustraction (-) et de division (/), ainsi que la fonction ABS.
Colonne1Colonne2FormuleDescription
2 3422 500=(Colonne2-Colonne1)/ABS(Colonne1)Pourcentage de différence (6,75% ou 0,06746)

AfficherMultiplier des nombres

Utilisez l'opérateur de multiplication (*) ou la fonction PRODUIT pour effectuer cette opération.
Colonne1 Colonne2 FormuleDescription
52=Colonne1*Colonne2Multiplie entre eux les nombres des deux premières colonnes (10)
52=PRODUIT(Colonne1; Colonne2)Multiplie entre eux les nombres des deux premières colonnes (10)
52=PRODUIT(Colonne1;Colonne2;2)Multiplie entre eux les nombres des deux premières colonnes et le nombre 2 (20)

AfficherDiviser des nombres

Utilisez l'opérateur de division (/) pour effectuer cette opération.

Colonne1 Colonne2 Formule Description
15 000 12 =Colonne1/Colonne2 Divise 15 000 par 12 (1 250)
15 000 12 =(Colonne1+9000)/Colonne2 Additionne 15 000 et 9 000, puis divise le total par 12 (2 000)

AfficherCalculer la moyenne de nombres

La moyenne est également appelée moyenne arithmétique. Pour calculer la moyenne de nombres figurant dans deux colonnes ou plus d'une même ligne, utilisez la fonction MOYENNE.

Colonne1 Colonne2 Colonne3 Formule Description
6 5 4 =MOYENNE(Colonne1;Colonne2;Colonne3) Moyenne des nombres des trois premières colonnes (5)
6 5 4 =MOYENNE(SI(Colonne1>Colonne2; Colonne1-Colonne2; 10); Colonne3) Si Colonne1 est supérieur à Colonne2, calculer la moyenne de la différence entre ces deux nombres et de Colonne3. Sinon calculer la moyenne de la valeur 10 et de Colonne3. (2,5)

AfficherCalculer la médiane de nombres

La médiane est la valeur qui se trouve au milieu d'une série ordonnée de nombres. Utilisez la fonction MEDIANE pour calculer la médiane d'un groupe de nombres.
A B CDEFFormuleDescription
10 792704=MEDIANE(A; B; C; D; E; F)Médiane des nombres contenus dans les six premières colonnes (8)

AfficherCalculer le plus petit ou le plus grand nombre dans une série

Pour calculer le plus petit ou le plus grand nombre de deux colonnes ou plus d'une même ligne, utilisez les fonctions MIN et MAX.
Colonne1 Colonne2 Colonne3FormuleDescription
10 79=MIN(Colonne1; Colonne2; Colonne3)Plus petit nombre (7)
1079=MAX(Colonne1; Colonne2; Colonne3)Plus grand nombre (10)

AfficherCompter des valeurs

Pour compter des valeurs numériques, utilisez la fonction NB.
Colonne1 Colonne2 Colonne3FormuleDescription
Pomme12/12/2007=NB(Colonne1; Colonne2; Colonne3)Compte le nombre de colonnes contenant des valeurs numériques, y compris des valeurs de type date et heure. Exclut le texte et les valeurs null. (1)
12€#DIV/0!1,01=NB(Colonne1; Colonne2; Colonne3)Compte le nombre de colonnes contenant des valeurs numériques, mais exclut les valeurs de type erreur et logique (2)

AfficherAugmenter ou diminuer un nombre d'un certain pourcentage

Utilisez l'opérateur Pourcentage (%) pour effectuer cette opération.
Colonne1 Colonne2 FormuleDescription
233%=Colonne1*(1+5%)Augmente le nombre dans Column1 de 5% (24,15)
233%=Colonne1*(1+Colonne2)Augmente le nombre dans Colonne1 de la valeur en pour cent dans Colonne2 : 3% (23,69)
233%=Colonne1*(1-Colonne2)Diminue le nombre dans Colonne1 de la valeur en pour cent dans Colonne2 : 3% (22,31)

AfficherÉlever un nombre à une puissance

Utilisez l'opérateur Exposant (^) ou la fonction PUISSANCE pour effectuer cette opération.
Colonne1 Colonne2 FormuleDescription
52=Colonne1^Colonne2Calcule 5 au carré (25)
53=PUISSANCE(Colonne1; Colonne2)Calcule 5 au cube (125)

AfficherArrondir un nombre

Pour arrondir un nombre vers le haut, utilisez les fonctions ARRONDI.SUP, IMPAIR et PAIR.

Colonne1 Formule Description
20,3 =ARRONDI.SUP(Colonne1;0) Arrondit 20,3 vers le haut, à l'entier le plus proche (21)
-5,9 =ARRONDI.SUP(Colonne1;0) Arrondit -5,9 vers le haut (-6)
12,5493 =ARRONDI.SUP(Colonne1;2) Arrondit 12,5493 vers le haut, au centième le plus proche, avec deux décimales (12,55)
20,3 =PAIR(Colonne1) Arrondit 20,3 vers le haut, au nombre pair le plus proche (22)
20,3 =IMPAIR(Colonne1) Arrondit 20,3 vers le haut, au nombre impair le plus proche (21)

Pour arrondir un nombre vers le bas, utilisez la fonction ARRONDI.INF.

Colonne1 Formule Description
20,3 =ARRONDI.INF(Colonne1;0) Arrondit 20,3 vers le bas, à l'entier le plus proche (20)
-5,9 =ARRONDI.INF(Colonne1;0) Arrondit -5,9 vers le bas (-5)
12,5493 =ARRONDI.INF(Colonne1;2) Arrondit 12,5493 vers le bas, au centième le plus proche, avec deux décimales (12,54)

Pour arrondir un nombre vers le nombre ou la fraction décimale la plus proche, utilisez la fonction ARRONDI.

Colonne1 Formule Description
20,3 =ARRONDI(Colonne1;0) Arrondit 20,3 vers le bas, parce que la fraction décimale est inférieure à 0,5 (20)
5,9 =ARRONDI(Colonne1;0) Arrondit 5,9 vers le haut, parce que la fraction décimale est supérieure à 0,5 (6)
-5,9 =ARRONDI(Colonne1;0) Arrondit -5,9 vers le bas, parce que la fraction décimale est inférieure à 0,5 (-6)
1,25 =ARRONDI(Colonne1; 1) Arrondit le nombre au dixième le plus proche (une décimale). Comme la partie à arrondir est supérieure ou égale à 0,05, le nombre est arrondi vers le haut (résultat : 1,3)
30,452 =ARRONDI(Colonne1; 2) Arrondit le nombre au centième le plus proche (deux décimales). Comme la partie à arrondir, 0,002, est inférieure à 0,005, le nombre est arrondi vers le bas (résultat : 30,45)

Pour arrondir un nombre au chiffre significatif au dessus de 0, utilisez les fonctions ARRONDI, ARRONDI.SUP, ARRONDI.INF, ENT et NBCAR.

Colonne1 Formule Description
5 492 820 =ARRONDI(Colonne1;3-NBCAR(ENT(Colonne1))) Arrondit le nombre à trois chiffres significatifs (5 490 000)
22 230 =ARRONDI.INF(Colonne1;3-NBCAR(ENT(Colonne1))) Arrondit le nombre vers le bas, à trois chiffres significatifs (22 200)
5 492 820 =ARRONDI.SUP(Colonne1; 5-NBCAR(ENT(Colonne1))) Arrondit le nombre vers le haut à 5 chiffres significatifs (5 492 900)

Formules avec du texte

AfficherChanger la casse du texte

Utilisez les fonctions MAJUSCULE, MINUSCULE ou NOMPROPRE pour effectuer cette opération.
Colonne1FormuleDescription
nancy Davolio=MAJUSCULE(Colonne1)Change le texte en majuscules (NANCY DAVOLIO)
nancy Davolio=MINUSCULE(Colonne1)Change le texte en minuscules (nancy davolio)
nancy Davolio=NOMPROPRE(Colonne1)Change le texte avec la 1ère lettre des mots en majuscule (Nancy Davolio)

AfficherCombiner le prénom et le nom

Utilisez l'opérateur « et commercial »(&) ou la fonction CONCATENER pour effectuer cette opération.
Colonne1Colonne2FormuleDescription
NancyFuller=Colonne1&Colonne2Combine les deux chaînes (NancyFuller)
NancyFuller=Colonne1&" "&Colonne2Combine les deux chaînes, séparées par un espace (Nancy Fuller)
NancyFuller=Colonne2&","&Colonne1Combine les deux chaînes, séparées par une virgule (Fuller,Nancy)
Nancy Fuller=CONCATENER(Colonne2; ","; Colonne1)Combine les deux chaînes, séparées par une virgule (Fuller,Nancy)

AfficherCombiner du texte et des nombres provenant de différentes colonnes

Utilisez les fonctions CONCATENER et TEXTE, et l'opérateur « et commercial » (&) pour effectuer cette opération.
Colonne1Colonne2FormuleDescription
Dupont28=Colonne1&" vend "&Colonne2&" unités."Combine le contenu de ces deux colonnes en une phrase (Dupont vend 28 unités.)
Durant40%=Colonne1&" vend "&TEXTE(Colonne2;"0%")&" des ventes totales."Combine le contenu de ces deux colonnes en une phrase (Durand vend 40% des ventes totales.).

 Remarque   La fonction TEXTE ajoute la valeur formatée de Colonne2 au lieu de la valeur sous-jacente, qui est 0,4.

Dupont28=CONCATENER(Colonne1;" vend ";Colonne2;" unités.")Combine le contenu de ces deux colonnes en une phrase (Dupont vend 28 unités.)

AfficherCombiner du texte avec une date ou une heure

Utilisez la fonction TEXTE et l'opérateur « et commercial » (&) pour effectuer cette opération.
Colonne1Colonne2FormuleDescription
Date de facturation5-Juin-2007="Date de facture : "&TEXTE(Colonne2; "j-mmm-aaaa")Combine du texte avec une date (Date de facture : 5-Juin-2007)
Date de facturation5-Juin-2007=Colonne1&" "&TEXTE(Colonne2; "jj-mmm-aaaa")Combiner du texte avec une date provenant d'une autre colonne en une seule colonne (Date de facturation 05-jun-2007)

AfficherComparer le contenu de colonnes

Pour comparer une colonne à une autre colonne ou à une liste de valeurs, utilisez les fonctions EXACT et OU.
Colonne1Colonne2FormuleDescription
BD122BD123=EXACT(Colonne1;Colonne2) Comparer le contenu des deux premières colonnes (Non)
BD122BD123=EXACT(Colonne1; "BD122")Comparer le contenu de Colonne1 avec la chaîne « BD122 » (Oui)
BD122BD123=OU(EXACT("BD121"; Colonne1; Colonne2)Comparer la chaîne « BD121 » avec le contenu des deux premières colonnes (Non)

AfficherVérifier si la valeur d'une colonne ou une partie de celle-ci correspond à du texte spécifique

Pour vérifier si la valeur d'une colonne ou une partie de celle-ci correspond à du texte spécifique, utilisez SI, TROUVE, CHERCHE et ESTNUM.

Colonne1 Formule Description
Davolio =SI(Colonne1="Davolio"; "Oui"; "Non") Vérifie si le contenu de Colonne1 est Davolio (Oui)
Davolio =SI(ESTNUM(TROUVE("v";Colonne1)); "Oui"; "Non") Vérifie si Colonne1 contient la lettre v (Oui)
BD123 =ESTNUM(TROUVE("BD";Colonne1)) Vérifie si Colonne1 contient BD (Oui)

AfficherCompter les colonnes non vides

Utilisez la fonction NBVAL pour effectuer cette opération.
Colonne1Colonne2Colonne3FormuleDescription
Ventes19=NBVAL(Colonne1; Colonne2) Compte le nombre de colonnes non vides (2)
Ventes19=NBVAL(Colonne1; Colonne2; Colonne3)Compte le nombre de colonnes non vides (2)

AfficherSupprimer des caractères dans du texte

Utilisez les fonctions NBCAR, GAUCHE et DROITE pour effectuer cette opération.
Colonne1FormuleDescription
Vitamine A=GAUCHE(Colonne1;NBCAR(Colonne1)-2)Renvoie 8 (10-2) caractères à partir de la gauche (Vitamine)
Vitamine B1=DROITE(Colonne1; NBCAR(Colonne1)-9)Renvoie 2 (11-9) caractères à partir de la droite (B1)

AfficherSupprimer des espaces du début et de la fin d'une colonne

Utilisez la fonction SUPPRESPACE pour effectuer cette opération.
Colonne1FormuleDescription
  Bonjour !=SUPPRESPACE(Colonne1)Supprimer les espaces du début et de la fin (Bonjour !)

AfficherRépéter un caractère dans une colonne

Utilisez la fonction REPT pour effectuer cette opération.
FormuleDescription
=REPT(".";3)Répète un point 3 fois (...)
=REPT("-";10)Répète un tiret 10 fois (----------)

Autres formules

AfficherMasquer des valeurs d'erreur dans des colonnes

Pour afficher un tiret, #N/A ou NA à la place d'une valeur d'erreur, utilisez la fonction ESTERREUR.
Colonne1 Colonne2 FormuleDescription
100=Colonne1/Colonne2Génère une erreur (#DIV/0)
100=SI(ESTERREUR(Colonne1/Colonne2);"NA";Colonne1/Colonne2)Renvoie NA lorsque la valeur est une erreur
100=SI(ESTERREUR(Colonne1/Colonne2);"-";Colonne1/Colonne2)Renvoie un tiret lorsque la valeur est une erreur
previous page start next page