Function SET1935: iSeries Batch Printing Function

LANSA

previous page next page
Function SET1935: iSeries Batch Printing Function
********** COMMENT(=======================================================);
********** COMMENT(Process ........: SET_193);
********** COMMENT(Function .......: SET1935);
********** COMMENT(Created on .....: 12th October 2000);
********** COMMENT(Description ....: Demonstration Function 4);
********** COMMENT(Version.........: 1);
********** COMMENT();
********** COMMENT(Full Description: This function demonstrates);
********** COMMENT( how an AS/400 batch job can extract information from);
********** COMMENT( a DBMS table on a Windows NT/2000 system and print);
********** COMMENT( on the AS/400 system. Also see:);
********** COMMENT( SET1934: The function that submits this function);
********** COMMENT( SET1936: The Windows NT data extractor);
********** COMMENT();
********** COMMENT(Disclaimer: The following material is supplied as);
********** COMMENT( example material only. No warranty concerning this);
********** COMMENT( material or its use in any way whatsoever is);
********** COMMENT( expressed or implied.);
********** COMMENT();
********** COMMENT(Minimum Release of LANSA Required : 8.0);
********** COMMENT();
********** COMMENT(=======================================================);
FUNCTION OPTIONS(*DIRECT *LIGHTUSAGE);
********** COMMENT();
********** COMMENT(Define locally scoped fields);
********** COMMENT();
DEFINE FIELD(#NXT_EMPNO) REFFLD(#EMPNO) DEFAULT(*BLANKS);
DEFINE FIELD(#RET_COUNT) REFFLD(#STD_NUM) DESC('Number of rows returned');
DEFINE FIELD(#RET_STATE) REFFLD(#IO$STS) DESC('Status of last operation');
********** COMMENT();
********** COMMENT(Define the report);
********** COMMENT();
DEF_HEAD NAME(#HEADER) FIELDS((#FUNCDESC)(#REP1PAGE)(#DATE)(#TIME)) DESIGN(*DOWN);
DEF_LINE NAME(#DETAILS) FIELDS((#EMPNO)(#GIVENAME)(#SURNAME)(#SALARY));
********** COMMENT();
********** COMMENT(This is an AS/400 batch job. It is designed to get);
********** COMMENT(the number, name and salary details of all employees);
********** COMMENT(residing in table PSLMST on a Windows NT/2000 system);
********** COMMENT(and then print them on a simple AS/400 style report.);
********** COMMENT();
********** COMMENT();
********** COMMENT(Loop around printing details until the state field);
********** COMMENT(indicates that there is nothing more to do or that);
********** COMMENT(an error has occured);
********** COMMENT();
DOUNTIL COND('#RET_STATE *NE OK');
********** COMMENT();
********** COMMENT(Ask the NT/2000 system to return the next 10 details);
********** COMMENT((a higher factor than 10 could be used, but the low);
********** COMMENT(value of 10 demonstrates the blocking technique being);
********** COMMENT(used by this application);
********** COMMENT();
EXECUTE SUBROUTINE(BEGIN);
EXECUTE SUBROUTINE(PUT_ALPHA) WITH_PARMS('NEXT_EMPLOYEE' #NXT_EMPNO);
********** COMMENT();
********** COMMENT(Send/Receive details to/from the NT/2000 server system);
********** COMMENT();
EXECUTE SUBROUTINE(SEND) WITH_PARMS(GENL SET1936 *BLANKS);
EXECUTE SUBROUTINE(RECEIVE) WITH_PARMS(GENL 30);
********** COMMENT();
********** COMMENT(Get back basic details);
********** COMMENT();
EXECUTE SUBROUTINE(GET_ALPHA) WITH_PARMS('RET_STATE' #RET_STATE EF);
EXECUTE SUBROUTINE(GET_NUMBER) WITH_PARMS('RET_COUNT' #RET_COUNT 0);
EXECUTE SUBROUTINE(GET_ALPHA) WITH_PARMS('NEXT_EMPLOYEE' #NXT_EMPNO #NXT_EMPNO);
********** COMMENT();
********** COMMENT(Now loop around and print the returned details);
********** COMMENT();
BEGIN_LOOP TO(#RET_COUNT);
EXECUTE SUBROUTINE(GET_ALPHA) WITH_PARMS(EMPNO #EMPNO *BLANKS);
EXECUTE SUBROUTINE(GET_ALPHA) WITH_PARMS(SURNAME #SURNAME *BLANKS);
EXECUTE SUBROUTINE(GET_ALPHA) WITH_PARMS(GIVENAME #GIVENAME *BLANKS);
EXECUTE SUBROUTINE(GET_NUMBER) WITH_PARMS(SALARY #SALARY 0);
PRINT LINE(#DETAILS);
EXECUTE SUBROUTINE(NEXT_SET);
END_LOOP;
ENDUNTIL;
********** COMMENT();
********** COMMENT(Finished ! End all activities);
********** COMMENT();
EXECUTE SUBROUTINE(ENDSERVICE);
ENDPRINT;
RETURN;
********** COMMENT(============================================);
********** COMMENT(============================================);
********** COMMENT(============================================);
********** COMMENT(==== Windows NT/2000 Interface Routines ====);
********** COMMENT(============================================);
********** COMMENT(============================================);
********** COMMENT(============================================);
********** COMMENT(These subroutines are used to simplify and);
********** COMMENT( standardize interfacing with a NT/2000);
********** COMMENT( service via function SET193T);
********** COMMENT(============================================);
********** COMMENT(============================================);
********** COMMENT(============================================);
********** COMMENT(============================================);
********** COMMENT(Begin: Sets or Resets an interaction between);
********** COMMENT( this program and an NT/2000 server. Use);
********** COMMENT( this subroutine at the start of each);
********** COMMENT( logical transaction.);
********** COMMENT(============================================);
SUBROUTINE NAME(BEGIN);
CHANGE FIELD(#S_193GSR) TO(I);
EXCHANGE FIELDS(#S_193GSR);
EXECUTE SUBROUTINE(CALL_193T);
EXECUTE SUBROUTINE(FIRST_SET);
ENDROUTINE;
********** COMMENT(============================================);
********** COMMENT(EndService: Ends any existing connection with);
********** COMMENT( an NT/200 server and frees resources. Use);
********** COMMENT( when all interactions have been completed.);
********** COMMENT(============================================);
SUBROUTINE NAME(ENDSERVICE);
CHANGE FIELD(#S_193GSR) TO(T);
EXCHANGE FIELDS(#S_193GSR);
EXECUTE SUBROUTINE(CALL_193T);
ENDROUTINE;
********** COMMENT(============================================);
********** COMMENT(First_Set : Sets up for the processing the);
********** COMMENT( first set of variable instances);
********** COMMENT(============================================);
SUBROUTINE NAME(FIRST_SET);
CHANGE FIELD(#S_193VIN) TO(1);
ENDROUTINE;
********** COMMENT(============================================);
********** COMMENT(Next_Set : Sets up for the processing the);
********** COMMENT( next set of variable instances);
********** COMMENT(============================================);
SUBROUTINE NAME(NEXT_SET);
CHANGE FIELD(#S_193VIN) TO('#S_193VIN + 1');
ENDROUTINE;
********** COMMENT(================================================);
********** COMMENT(Put_Alpha: Set the value of an alpha variable);
********** COMMENT( instance. Used as Put_Alpha ( <nam> <val> ));
********** COMMENT( where :);
********** COMMENT( <nam> is the variable's symbolic name);
********** COMMENT( <val> is the variable value);
********** COMMENT(================================================);
SUBROUTINE NAME(PUT_ALPHA) PARMS((#S_193VNM *RECEIVED) (#S_193VAV *RECEIVED));
CHANGE FIELD(#S_193GSR) TO(A);
EXCHANGE FIELDS(#S_193GSR #S_193VNM #S_193VIN #S_193VAV);
EXECUTE SUBROUTINE(CALL_193T);
ENDROUTINE;
********** COMMENT(================================================);
********** COMMENT(Put_Number: Set the value of a numeric variable);
********** COMMENT( instance. Used as Put_Number ( <nam> <val> ));
********** COMMENT( where :);
********** COMMENT( <nam> is the variable's symbolic name);
********** COMMENT( <val> is the variable value);
********** COMMENT(================================================);
SUBROUTINE NAME(PUT_NUMBER) PARMS((#S_193VNM *RECEIVED) (#S_193VNV *RECEIVED));
CHANGE FIELD(#S_193GSR) TO(B);
EXCHANGE FIELDS(#S_193GSR #S_193VNM #S_193VIN #S_193VNV);
EXECUTE SUBROUTINE(CALL_193T);
ENDROUTINE;
********** COMMENT(================================================);
********** COMMENT(Get_Alpha: Get the value of an alpha variable);
********** COMMENT( instance. Used as Get_Alpha (<nam> <val> <dft>));
********** COMMENT( where :);
********** COMMENT( <nam> is the variable's symbolic name);
********** COMMENT( <val> is the variable's returned value);
********** COMMENT( <dft> is the variable's default value);
********** COMMENT(================================================);
SUBROUTINE NAME(GET_ALPHA) PARMS((#S_193VNM *RECEIVED) (#S_193VAV *RETURNED) (#D_193VAV *RECEIVED));
DEFINE FIELD(#D_193VAV) REFFLD(#S_193VAV) DESC('Alphanumeric Default Value');
CHANGE FIELD(#S_193GSR) TO(C);
CHANGE FIELD(#S_193VAV) TO(#D_193VAV);
EXCHANGE FIELDS(#S_193GSR #S_193VNM #S_193VIN #S_193VAV);
EXECUTE SUBROUTINE(CALL_193T);
ENDROUTINE;
********** COMMENT(================================================);
********** COMMENT(Get_Number: Get the value of a numeric variable);
********** COMMENT( instance. Used as Get_Number (<nam> <val> <dft>));
********** COMMENT( where :);
********** COMMENT( <nam> is the variable's symbolic name);
********** COMMENT( <val> is the variable's returned value);
********** COMMENT( <dft> is the variable's default value);
********** COMMENT(================================================);
SUBROUTINE NAME(GET_NUMBER) PARMS((#S_193VNM *RECEIVED) (#S_193VNV *RETURNED) (#D_193VNV *RECEIVED));
DEFINE FIELD(#D_193VNV) REFFLD(#S_193VNV) DESC('Numeric Default Value');
CHANGE FIELD(#S_193GSR) TO(D);
CHANGE FIELD(#S_193VNV) TO(#D_193VNV);
EXCHANGE FIELDS(#S_193GSR #S_193VNM #S_193VIN #S_193VNV);
EXECUTE SUBROUTINE(CALL_193T);
ENDROUTINE;
********** COMMENT(================================================);
********** COMMENT(Send: Send all variables to a service);
********** COMMENT( Used as Send ( <nam> <fun> <com> ));
********** COMMENT( where :);
********** COMMENT( <nam> is the service symbolic name);
********** COMMENT( <fun> is the RDML function to invoke);
********** COMMENT( <com> is the RDML component to invoke);
********** COMMENT(================================================);
SUBROUTINE NAME(SEND) PARMS((#S_193SERV *RECEIVED) (#S_193FUN *RECEIVED) (#S_193COM *RECEIVED));
CHANGE FIELD(#S_193GSR) TO(S);
EXCHANGE FIELDS(#S_193GSR #S_193SERV #S_193FUN #S_193COM);
EXECUTE SUBROUTINE(CALL_193T);
ENDROUTINE;
********** COMMENT(================================================);
********** COMMENT(Receive: Receive all variables from a service);
********** COMMENT( Used as Receive ( <nam> <max> ));
********** COMMENT( where :);
********** COMMENT( <nam> is the service symbolic name);
********** COMMENT( <max> is the maximum time to wait);
********** COMMENT(================================================);
SUBROUTINE NAME(RECEIVE) PARMS((#S_193SERV *RECEIVED) (#S_193MAXW *RECEIVED));
CHANGE FIELD(#S_193GSR) TO(R);
EXCHANGE FIELDS(#S_193GSR #S_193SERV #S_193MAXW);
EXECUTE SUBROUTINE(CALL_193T);
EXECUTE SUBROUTINE(FIRST_SET);
ENDROUTINE;
********** COMMENT(================================================);
********** COMMENT(Call_193T: Used to call function SET193T);
********** COMMENT(================================================);
SUBROUTINE NAME(CALL_193T);
CALL PROCESS(*DIRECT) FUNCTION(SET193T);
ENDROUTINE;
previous page start next page