Reusable Part S_174RWB: Web Browser Active-X Wrapper

LANSA

previous page next page
Reusable Part S_174RWB: Web Browser Active-X Wrapper
* ===================================================================
*
* Component : S_174RWB
* Type : Resuable Part
* Ancestor : PRIM_PANL
*
* Description : Web Browser Active-X Wrapper
*
* Disclaimer : The following material is supplied as sample material
* only. No warranty concerning this material or its use
* in any way whatsoever is expressed or implied.
*
* ===================================================================
FUNCTION OPTIONS(*DIRECT)
BEGIN_COM DISPLAYPOSITION(1) HEIGHT(151) LAYOUTMANAGER(#ATLM_1) LEFT(0) TABPOSITION(1) TOP(0) WIDTH(181)
DEFINE_COM CLASS(#S_174XWB.WebBrowser) NAME(#BROWSER) DISPLAYPOSITION(1) HEIGHT(151) LEFT(0) PARENT(#COM_OWNER) TABPOSITION(1) TOP(0) WIDTH(181)
DEFINE_COM CLASS(#PRIM_ATLM) NAME(#ATLM_1)
DEFINE_COM CLASS(#PRIM_ATLI) NAME(#ATLI_1) ATTACHMENT(Center) MANAGE(#BROWSER) PARENT(#ATLM_1)
DEFINE_COM CLASS(#SYSVAR$AV) NAME(#DOCUMENT)

Define_Evt uLoadStarted
Define_Map *Input #SysVar$av #ForDocument
Define_Evt uLoadEnded
Define_Map *Input #SysVar$av #ForDocument

MthRoutine uShow
Define_Map *Input #SysVar$av #URL
Set #Document Value(#Url)
Signal uLoadStarted ForDocument(#Document)
Invoke #Browser.Stop
Invoke #Browser.Navigate URL(#URL)
EndRoutine

EVTROUTINE HANDLING(#BROWSER.DocumentComplete) OPTIONS(*NOCLEARMESSAGES *NOCLEARERRORS)
Signal uLoadEnded ForDocument(#Document)
ENDROUTINE

END_COM
previous page start next page