Function SET1938: Windows NT Side of SET1937

LANSA

previous page next page
Function SET1938: Windows NT Side of SET1937
********** COMMENT(=======================================================);
********** COMMENT(Process ........: SET_193);
********** COMMENT(Function .......: SET1938);
********** COMMENT(Created on .....: 12th October 2000);
********** COMMENT(Description ....: Demonstration Function 5);
********** COMMENT(Version.........: 1);
********** COMMENT();
********** COMMENT(Full Description: This function demonstrates);
********** COMMENT( how an AS/400 function can read data from the);
********** COMMENT( Windows NT/2000 file system system);
********** COMMENT();
********** COMMENT(Disclaimer: The following material is supplied as);
********** COMMENT( example material only. No warranty concerning this);
********** COMMENT( material or its use in any way whatsoever is);
********** COMMENT( expressed or implied.);
********** COMMENT();
********** COMMENT(Minimum Release of LANSA Required : 8.0);
********** COMMENT();
********** COMMENT(=======================================================);
FUNCTION OPTIONS(*DIRECT *HEAVYUSAGE);
********** COMMENT();
********** COMMENT(Define local variables);
********** COMMENT();
DEFINE FIELD(#S_193VFIL) TYPE(*CHAR) LENGTH(200) DESC('NT/2000 File Name (eg: C:\AUTOEXEC.BAT)') INPUT_ATR(LC);
DEFINE FIELD(#S_193STS) TYPE(*CHAR) LENGTH(002) DESC('Operation status');
DEF_LIST NAME(#S_193LST1) FIELDS(#SYSVAR$AV) TYPE(*WORKING) ENTRYS(0009999);
DEF_LIST NAME(#S_193LST2) FIELDS(#SYSVAR$AV) TYPE(*WORKING) ENTRYS(0000001);
DEFINE FIELD(#S_193SRC) REFFLD(#STD_NUM);
DEFINE FIELD(#S_193TRR) REFFLD(#STD_NUM);
DEFINE FIELD(#S_193TRW) REFFLD(#STD_NUM);
********** COMMENT();
********** COMMENT(Get the requested action code to work out what to do);
********** COMMENT();
EXECUTE SUBROUTINE(FIRST_SET);
EXECUTE SUBROUTINE(GET_ALPHA) WITH_PARMS(ACTION #STD_OBJ *BLANKS);
********** COMMENT();
********** COMMENT(handle various different actions);
********** COMMENT();
CASE OF_FIELD(#STD_OBJ);
********** COMMENT();
********** COMMENT(Handle a EXISTS request);
********** COMMENT();
WHEN VALUE_IS('= EXISTS');
EXECUTE SUBROUTINE(GET_ALPHA) WITH_PARMS('FILE_NAME' #S_193VFIL *BLANKS);
USE BUILTIN(OV_FILE_SERVICE) WITH_ARGS('CHECK_FILE' #S_193VFIL) TO_GET(#S_193STS);
EXECUTE SUBROUTINE(BEGIN);
EXECUTE SUBROUTINE(PUT_ALPHA) WITH_PARMS(STATUS #S_193STS);
********** COMMENT();
********** COMMENT(Handle a LOAD request statelessly);
********** COMMENT();
WHEN VALUE_IS('= LOAD');
EXECUTE SUBROUTINE(GET_ALPHA) WITH_PARMS('FILE_NAME' #S_193VFIL *BLANKS);
EXECUTE SUBROUTINE(GET_NUMBER) WITH_PARMS('LAST_ROW' #S_193SRC 0);
EXECUTE SUBROUTINE(BEGIN);
********** COMMENT();
CHANGE FIELD(#S_193TRR #S_193TRW) TO(0);
DOUNTIL COND('(#S_193STS = EF) OR (#S_193STS = ER)');
CLR_LIST NAMED(#S_193LST1);
USE BUILTIN(TRANSFORM_FILE) WITH_ARGS(#S_193LST1 #S_193VFIL T B Y '.' N) TO_GET(#S_193STS);
SELECTLIST NAMED(#S_193LST1);
IF COND('#S_193TRW >= 100');
EXECUTE SUBROUTINE(FIRST_SET);
EXECUTE SUBROUTINE(PUT_NUMBER) WITH_PARMS('ROWS_RETURNED' #S_193TRW);
EXECUTE SUBROUTINE(PUT_NUMBER) WITH_PARMS('LAST_ROW' #S_193TRR);
EXECUTE SUBROUTINE(PUT_ALPHA) WITH_PARMS(STATUS OV);
USE BUILTIN(TRANSFORM_FILE) WITH_ARGS(#S_193LST2 #S_193VFIL T B Y '.' Y) TO_GET(#S_193STS);
RETURN;
ENDIF;
CHANGE FIELD(#S_193TRR) TO('#S_193TRR + 1');
IF COND('#S_193TRR > #S_193SRC');
CHANGE FIELD(#S_193TRW) TO('#S_193TRW + 1');
EXECUTE SUBROUTINE(PUT_ALPHA) WITH_PARMS('FILE_RECORD' #SYSVAR$AV);
EXECUTE SUBROUTINE(NEXT_SET);
ENDIF;
ENDSELECT;
ENDUNTIL;
********** COMMENT();
EXECUTE SUBROUTINE(FIRST_SET);
EXECUTE SUBROUTINE(PUT_NUMBER) WITH_PARMS('ROWS_RETURNED' #S_193TRW);
EXECUTE SUBROUTINE(PUT_NUMBER) WITH_PARMS('LAST_ROW' #S_193TRR);
EXECUTE SUBROUTINE(PUT_ALPHA) WITH_PARMS(STATUS EF);
********** COMMENT();
********** COMMENT(Handle an unknown request);
********** COMMENT();
OTHERWISE;
MESSAGE MSGTXT('Unknown request received by SET1938');
ENDCASE;
********** COMMENT();
********** COMMENT(Finished);
********** COMMENT();
RETURN;
********** COMMENT(============================================);
********** COMMENT(============================================);
********** COMMENT(============================================);
********** COMMENT(==== Windows NT/2000 Interface Routines ====);
********** COMMENT(============================================);
********** COMMENT(============================================);
********** COMMENT(============================================);
********** COMMENT(These subroutines are used to simplify and);
********** COMMENT( standardize interfacing with a NT/2000);
********** COMMENT( service via function SET193T);
********** COMMENT(============================================);
********** COMMENT(============================================);
********** COMMENT(============================================);
********** COMMENT(============================================);
********** COMMENT(Begin: Sets or Resets an interaction between);
********** COMMENT( this program and an NT/2000 server. Use);
********** COMMENT( this subroutine at the start of each);
********** COMMENT( logical transaction.);
********** COMMENT(============================================);
SUBROUTINE NAME(BEGIN);
CHANGE FIELD(#S_193GSR) TO(I);
EXCHANGE FIELDS(#S_193GSR);
EXECUTE SUBROUTINE(CALL_193T);
EXECUTE SUBROUTINE(FIRST_SET);
ENDROUTINE;
********** COMMENT(============================================);
********** COMMENT(EndService: Ends any existing connection with);
********** COMMENT( an NT/200 server and frees resources. Use);
********** COMMENT( when all interactions have been completed.);
********** COMMENT(============================================);
SUBROUTINE NAME(ENDSERVICE);
CHANGE FIELD(#S_193GSR) TO(T);
EXCHANGE FIELDS(#S_193GSR);
EXECUTE SUBROUTINE(CALL_193T);
ENDROUTINE;
********** COMMENT(============================================);
********** COMMENT(First_Set : Sets up for the processing the);
********** COMMENT( first set of variable instances);
********** COMMENT(============================================);
SUBROUTINE NAME(FIRST_SET);
CHANGE FIELD(#S_193VIN) TO(1);
ENDROUTINE;
********** COMMENT(============================================);
********** COMMENT(Next_Set : Sets up for the processing the);
********** COMMENT( next set of variable instances);
********** COMMENT(============================================);
SUBROUTINE NAME(NEXT_SET);
CHANGE FIELD(#S_193VIN) TO('#S_193VIN + 1');
ENDROUTINE;
********** COMMENT(================================================);
********** COMMENT(Put_Alpha: Set the value of an alpha variable);
********** COMMENT( instance. Used as Put_Alpha ( <nam> <val> ));
********** COMMENT( where :);
********** COMMENT( <nam> is the variable's symbolic name);
********** COMMENT( <val> is the variable value);
********** COMMENT(================================================);
SUBROUTINE NAME(PUT_ALPHA) PARMS((#S_193VNM *RECEIVED) (#S_193VAV *RECEIVED));
CHANGE FIELD(#S_193GSR) TO(A);
EXCHANGE FIELDS(#S_193GSR #S_193VNM #S_193VIN #S_193VAV);
EXECUTE SUBROUTINE(CALL_193T);
ENDROUTINE;
********** COMMENT(================================================);
********** COMMENT(Put_Number: Set the value of a numeric variable);
********** COMMENT( instance. Used as Put_Number ( <nam> <val> ));
********** COMMENT( where :);
********** COMMENT( <nam> is the variable's symbolic name);
********** COMMENT( <val> is the variable value);
********** COMMENT(================================================);
SUBROUTINE NAME(PUT_NUMBER) PARMS((#S_193VNM *RECEIVED) (#S_193VNV *RECEIVED));
CHANGE FIELD(#S_193GSR) TO(B);
EXCHANGE FIELDS(#S_193GSR #S_193VNM #S_193VIN #S_193VNV);
EXECUTE SUBROUTINE(CALL_193T);
ENDROUTINE;
********** COMMENT(================================================);
********** COMMENT(Get_Alpha: Get the value of an alpha variable);
********** COMMENT( instance. Used as Get_Alpha (<nam> <val> <dft>));
********** COMMENT( where :);
********** COMMENT( <nam> is the variable's symbolic name);
********** COMMENT( <val> is the variable's returned value);
********** COMMENT( <dft> is the variable's default value);
********** COMMENT(================================================);
SUBROUTINE NAME(GET_ALPHA) PARMS((#S_193VNM *RECEIVED) (#S_193VAV *RETURNED) (#D_193VAV *RECEIVED));
DEFINE FIELD(#D_193VAV) REFFLD(#S_193VAV) DESC('Alphanumeric Default Value');
CHANGE FIELD(#S_193GSR) TO(C);
CHANGE FIELD(#S_193VAV) TO(#D_193VAV);
EXCHANGE FIELDS(#S_193GSR #S_193VNM #S_193VIN #S_193VAV);
EXECUTE SUBROUTINE(CALL_193T);
ENDROUTINE;
********** COMMENT(================================================);
********** COMMENT(Get_Number: Get the value of a numeric variable);
********** COMMENT( instance. Used as Get_Number (<nam> <val> <dft>));
********** COMMENT( where :);
********** COMMENT( <nam> is the variable's symbolic name);
********** COMMENT( <val> is the variable's returned value);
********** COMMENT( <dft> is the variable's default value);
********** COMMENT(================================================);
SUBROUTINE NAME(GET_NUMBER) PARMS((#S_193VNM *RECEIVED) (#S_193VNV *RETURNED) (#D_193VNV *RECEIVED));
DEFINE FIELD(#D_193VNV) REFFLD(#S_193VNV) DESC('Numeric Default Value');
CHANGE FIELD(#S_193GSR) TO(D);
CHANGE FIELD(#S_193VNV) TO(#D_193VNV);
EXCHANGE FIELDS(#S_193GSR #S_193VNM #S_193VIN #S_193VNV);
EXECUTE SUBROUTINE(CALL_193T);
ENDROUTINE;
********** COMMENT(================================================);
********** COMMENT(Send: Send all variables to a service);
********** COMMENT( Used as Send ( <nam> <fun> <com> ));
********** COMMENT( where :);
********** COMMENT( <nam> is the service symbolic name);
********** COMMENT( <fun> is the RDML function to invoke);
********** COMMENT( <com> is the RDML component to invoke);
********** COMMENT(================================================);
SUBROUTINE NAME(SEND) PARMS((#S_193SERV *RECEIVED) (#S_193FUN *RECEIVED) (#S_193COM *RECEIVED));
CHANGE FIELD(#S_193GSR) TO(S);
EXCHANGE FIELDS(#S_193GSR #S_193SERV #S_193FUN #S_193COM);
EXECUTE SUBROUTINE(CALL_193T);
ENDROUTINE;
********** COMMENT(================================================);
********** COMMENT(Receive: Receive all variables from a service);
********** COMMENT( Used as Receive ( <nam> <max> ));
********** COMMENT( where :);
********** COMMENT( <nam> is the service symbolic name);
********** COMMENT( <max> is the maximum time to wait);
********** COMMENT(================================================);
SUBROUTINE NAME(RECEIVE) PARMS((#S_193SERV *RECEIVED) (#S_193MAXW *RECEIVED));
CHANGE FIELD(#S_193GSR) TO(R);
EXCHANGE FIELDS(#S_193GSR #S_193SERV #S_193MAXW);
EXECUTE SUBROUTINE(CALL_193T);
EXECUTE SUBROUTINE(FIRST_SET);
ENDROUTINE;
********** COMMENT(================================================);
********** COMMENT(Call_193T: Used to call function SET193T);
********** COMMENT(================================================);
SUBROUTINE NAME(CALL_193T);
CALL PROCESS(*DIRECT) FUNCTION(SET193T);
ENDROUTINE;
previous page start next page