Function SET184P

LANSA

previous page next page
Function SET184P

********** COMMENT(=======================================================);
********** COMMENT(Process ........: SET_184);
********** COMMENT(Function .......: SET184P);
********** COMMENT(Created on .....: 26/07/00 at 14:43:32);
********** COMMENT(Description ....: Hyperlinked Image to a static page);
********** COMMENT(Version.........: 1);
********** COMMENT();
********** COMMENT(Full Description: The purpose of this function is to);
********** COMMENT(show how an image can be displayed on each browselist);
********** COMMENT(entry. When the user clicks on the image they are);
********** COMMENT(taken to a static page for that product.);
********** COMMENT();
********** COMMENT(Disclaimer: The following material is supplied as an);
********** COMMENT(example only. No warranty is expressed or implied.);
********** COMMENT();
********** COMMENT(Receives: nothing);
********** COMMENT();
********** COMMENT(=======================================================);
********** COMMENT(Function control options);
FUNCTION OPTIONS(*DIRECT *WEBEVENT);
********** COMMENT();
********** COMMENT(Group and field definitions);
********** COMMENT();
DEFINE FIELD(#S_184P) TYPE(*CHAR) LENGTH(256) COLHDG('Image');
********** COMMENT((This field has attached component S_184P which);
********** COMMENT(displays the image for the browselist entry, and links);
********** COMMENT(to the static page for the product));
DEFINE FIELD(#S_184P1) TYPE(*CHAR) LENGTH(256);
********** COMMENT(this field holds the URL of the static page);
********** COMMENT();
********** COMMENT();
GROUP_BY NAME(#S_GRPPANL) FIELDS((#S_184FDES *INPUT *NOID)(#S_FUNDES *HIDDEN));
********** COMMENT((Field #S_184FDES has a component S_184FDES which);
********** COMMENT(merges in a component with the same name as the);
********** COMMENT(function (in this case component SET184P)));
********** COMMENT();
DEF_LIST NAME(#S_184PFVC) FIELDS((#S_184CDE)(#S_184DES)(#S_184QTY)(#S_184UNIT)(#S_184UPRC)(#S_184TPRC)(#S_184IMG *HIDDEN)(#S_184P1 *HIDDEN)(#S_184P *INPUT));
DEF_LIST NAME(#S_WRKFVC) FIELDS((#S_184CDE)(#S_184DES)(#S_184QTY)(#S_184UNIT)(#S_184UPRC)(#S_184TPRC)(#S_184IMG)) TYPE(*WORKING) ENTRYS(0000500);
********** COMMENT();
********** COMMENT(Mainline);
********** COMMENT();
CHANGE FIELD(#S_FUNDES) TO(*FUNCTION_DESC);
********** COMMENT();
CLR_LIST NAMED(#S_184PFVC);
********** COMMENT(Function SET184Y populates list #S_WRKFVC with data);
CALL PROCESS(*DIRECT) FUNCTION(SET184Y) PASS_LST(#S_WRKFVC );
SELECTLIST NAMED(#S_WRKFVC);
********** COMMENT(build the URL of the image);
USE BUILTIN(TCONCAT) WITH_ARGS(*S_IFSPATH '/' #S_184IMG) TO_GET(#S_184P);
********** COMMENT(build the URL of the static page);
USE BUILTIN(TCONCAT) WITH_ARGS(*S_IFSPATH '/' 'S_1841' #S_184CDE '.htm') TO_GET(#S_184P1);
********** COMMENT();
ADD_ENTRY TO_LIST(#S_184PFVC);
ENDSELECT;
********** COMMENT();
REQUEST FIELDS(#S_GRPPANL) BROWSELIST(#S_184PFVC) EXIT_KEY(*NO) MENU_KEY(*NO) PROMPT_KEY(*NO);
********** COMMENT(Field #S_184P has an attached component. This component);
********** COMMENT(displays the image and links to the static page for);
********** COMMENT(the product.);
********** COMMENT();
********** COMMENT(Note that #S_184P has been defined *INPUT on the);
********** COMMENT(DEF_LIST, to match the Visual Input component S_184P.);


previous page start next page