ChSegment Object

Microsoft Office Web Components Visual Basic

ChSegment Object

ChFormatMap ChSegments
ChSegment
ChSegmentBoundary

Represents a single segment in a format map. Each segment of a format map can be formatted independently of the other segments.

Using the ChSegment object

The following methods and properties return a ChSegment object.

The ChSegments object's Add method

The ChSegments object's Item property

Use the Add method of the ChSegments object to create a new segment. Use the properties of the ChSegmentBoundary object returned by the Begin property to format the beginning of a segment. Use the properties of the ChSegmentBoundary object returned by the End property to format the end of a segment.

Example

The following example binds Chartspace1 to the Order Details table in the Northwind database. Then, two segments are created. The first segment highlights the lowest 10% of values in the first series in the chart. The second segment highlights the top 20% of values in the first series in the chart.

Sub Window_Onload()

    Dim serseries1
    Dim segBottom10Pct
    Dim segTop20Pct
    Dim chConstants

    Set chConstants = ChartSpace1.Constants

    ' The following two lines of code bind Chartspace1 to the Order Details table in the
    ' Northwind SQL Server database.

    ChartSpace1.ConnectionString = "Provider=SQLOLEDB.1;persist Security Info=TRUE;" & _
                                   "Integrated Security=SSPI;Initial Catalog=Northwind;Data Source=" & _
                                   "ServerName;"

    ChartSpace1.DataMember = "Order Details"

    ' The following two lines of code bind Chartspace1 to the Quantity and ProductID fields
    ' in the Order details table.
    ChartSpace1.SetData chConstants.chDimCategories, chConstants.chDataBound, "ProductID"
    ChartSpace1.SetData chConstants.chDimValues, chConstants.chDataBound, "Quantity"

    ' Create a format map.
    ChartSpace1.SetData chConstants.chDimFormatValues, chConstants.chDataBound, "Quantity"

    ' Set a variable to the first series in the first chart in Chartspace1.
    Set serseries1 = ChartSpace1.Charts(0).SeriesCollection(0)

    ' Add a segment to the format map. This segment will
    ' represent the bottom 10% of values in the chart.
    Set segBottom10Pct = serseries1.FormatMap.Segments.Add

    ' Measure the segment boundaries based upon a percentage.

    segBottom10Pct.Begin.ValueType = chConstants.chBoundaryValuePercent
    segBottom10Pct.End.ValueType = chConstants.chBoundaryValuePercent

    ' Set the beginning value to 0%, and the ending value to 10%
    segBottom10Pct.Begin.Value = 0
    segBottom10Pct.End.Value = 0.1

    ' Format the interior of the matching values.
    segBottom10Pct.Begin.Interior.Color = "red"
    segBottom10Pct.End.Interior.Color = "red"   

    ' Add a segment to the format map. This segment will
    ' represent the top 20% of values in the chart.

    Set segTop20Pct = serseries1.FormatMap.Segments.Add

    ' Measure the segment boundaries based upon a percentage.
    segTop20Pct.Begin.ValueType = chConstants.chBoundaryValuePercent
    segTop20Pct.End.ValueType = chConstants.chBoundaryValuePercent

    ' Set the beginning value to 80%, and the ending value to 100%.
    segTop20Pct.Begin.Value = 0.8
    segTop20Pct.End.Value = 1

    ' Format the interior of the matching values.
    segTop20Pct.Begin.Interior.Color = "green"
    segTop20Pct.End.Interior.Color = "green"

End Sub