Eksempler på vanlige formler

Microsoft Access Web Datasheet

previous page next page

Vis alt Vis alt

Eksempler på vanlige formler

 Obs!   Du kan bruke følgende eksempler i beregnede kolonner. Eksempler som ikke inkluderer kolonnereferanser, kan brukes til å angi standardverdien for en kolonne.

Betingede formler

VisKontrollere om et tall er større eller mindre enn enn et annet tall

Bruk HVIS-funksjonen til å gjøre denne oppgaven.

Kolonne1 Kolonne2 Formel Beskrivelse
15000 9000 =Kolonne1>Kolonne2 Er Kolonne1 større enn Kolonne2? (Ja)
15000 9000 =HVIS(Kolonne1<=Kolonne2; "OK"; "Ikke OK") Er Kolonne1 mindre enn eller lik Kolonne2? (Ikke OK)

VisReturnere en logisk verdi etter en sammenligning av kolonneinnhold

Hvis resultatet skal være en logisk verdi (Ja eller Nei), bruker du funksjonene OG, ELLER og IKKE.
Kolonne1Kolonne2Kolonne3FormelBeskrivelse
1598=OG(Kolonne1>Kolonne2; Kolonne1<Kolonne3)Er 15 større enn 9 og mindre enn 8? (Nei)
1598=ELLER(Kolonne1>Kolonne2; Kolonne1<Kolonne3)Er 15 større enn 9 eller mindre enn 8? (Ja)
1598=IKKE(Kolonne1+Kolonne2=24)Er 15 pluss 9 ikke lik 24? (Nei)

Hvis du vil ha et resultat som er en annen beregning, eller en annen verdi enn Ja eller Nei, bruker du funksjonene HVIS, OG og ELLER.

Kolonne1Kolonne2Kolonne3FormelBeskrivelse
1598=HVIS(Kolonne1=15; "OK"; "Ikke OK")Hvis verdien i Kolonne1 er lik 15, returneres "OK". (OK)
1598=HVIS(OG(Kolonne1>Kolonne2; Kolonne1<Kolonne3); "OK"; "Ikke OK")Hvis 15 er større enn 9 og mindre enn 8, returneres "OK". (Ikke OK)
1598=HVIS(ELLER(Kolonne1>Kolonne2; Kolonne1<Kolonne3); "OK"; "Ikke OK")Hvis 15 er større enn 9 eller mindre enn 8, returneres "OK". (OK)

VisVise nuller som tomme eller streker

Bruk HVIS-funksjonen til denne oppgaven
Kolonne1Kolonne2FormelBeskrivelse
1010=Kolonne1-Kolonne2Det andre tallet subtraheres fra det første (0)
1010=HVIS(Kolonne1-Kolonne2;"";Kolonne1-Kolonne2)Returnerer null når verdien er null (tom kolonne)
159=HVIS(Kolonne1-Kolonne2;"-";Kolonne1-Kolonne2)Returnerer en strek når verdien er null (-)

Dato- og klokkeslettformler

VisLegge til datoer

Hvis du vil legge til et antall dager til en dato, bruker du addisjonsoperatoren (+). Legg merke til at når du manipulerer datoer, må returtypen til den beregnede kolonnen angis som Dato og klokkeslett.
Kolonne1Kolonne2FormelBeskrivelse
9/6/20073=Kolonne1+Kolonne2Adderer 3 dager til 9/6/2007 (12/6/2007)
10/12/200854=Kolonne1+Kolonne2Adderer 54 dager til 10/12/2008 (2/2/2009)

Hvis du vil addere et antall måneder til en dato, bruker du funksjonene DATO, ÅR, MÅNED og DAG.

Kolonne1Kolonne2FormelBeskrivelse
9/6/20073=DATO(ÅR(Kolonne1);MÅNED(Kolonne1)+Kolonne2;DAG(Kolonne1))Adderer 3 måneder til 9/6/2007 (9/9/2007)
10/12/200825=DATO(ÅR(Kolonne1);MÅNED(Kolonne1)+Kolonne2;DAG(Kolonne1))Adderer 25 måneder til 10/12/2008 (10/1/2011)

Hvis du vil addere et antall år til en dato, bruker du funksjonene DATO, ÅR, MÅNED og DAG.

Kolonne1Kolonne2FormelBeskrivelse
9/6/20073=DATO(ÅR(Kolonne1)+Kolonne2,MÅNED(Kolonne1),DAG(Kolonne1))Adderer 3 år til 9/6/2007 (9/6/2010)
10/12/200825=DATO(ÅR(Kolonne1)+Kolonne2;MÅNED(Kolonne1);DAG(Kolonne1))Adderer 25 år til 10/12/2008 (10/12/2033)

Hvis du vil legge til en kombinasjon av dager, måneder og år til en dato, bruker du funksjonene DATO, ÅR, MÅNED og DAG.

Kolonne1FormelBeskrivelse
9/6/2007=DATO(ÅR(Kolonne1)+3;MÅNED(Kolonne1)+1;DAG(Kolonne1)+5)Adderer 3 år, 1 måned og 5 dager til 9/6/2007 (14/7/2010)
10/12/2008=DATO(ÅR(Kolonne1)+1;MÅNED(Kolonne1)+7;DAG(Kolonne1)+5)Adderer 1 år, 7 måneder og 5 dager til 9/6/2007 (14/1/2009)

VisBeregne forskjellen mellom to datoer

Bruk DATODIFF-funksjonen til denne oppgaven.
Kolonne1Kolonne2FormelBeskrivelse
01-jan-199515-jun-1999=DATODIFF(Kolonne1; Kolonne2;"d")Returnerer antall dager mellom de to datoene(1626)
01-jan-199515-jun-1999=DATODIFF(Kolonne1; Kolonne2;"ym")Returnerer antall måneder mellom datoene, og ignorerer år-delen (5)
01-jan-199515-jun-1999=DATODIFF(Kolonne1; Kolonne2;"yd")Returnerer antall dager mellom datoene og ignorerer år-delen (165)

VisBeregne forskjellen mellom to tidspunkt

Hvis du vil presentere resultatet i standard tidsformat (timer:minutter:sekunder), bruker du subtraksjonsoperatoren (-) og TEKST-funksjonen.

Hvis denne metoden skal fungere, må ikke timer overskride 24, og minutter og sekunder må ikke overskride 60.

Kolonne1Kolonne2FormelBeskrivelse
09/06/2007 10:3509/06/2007 15:30=TEKST(Kolonne2-Kolonne1;"h")Timer mellom to tidspunkt (4)
09/06/2007 10:3509/06/2007 15:30=TEKST(Kolonne2-Kolonne1;"h:mm")Timer og minutter mellom to klokkeslett (4:55)
09/06/2007 10:3509/06/2007 15:30=TEKST(Kolonne2-Kolonne1;"h:mm:ss")Timer,minutter og sekunder mellom to tidspunkt (4:55:00)

Hvis du skal presentere resultatet i én summering basert på én tidsenhet, bruker du HELTALL-funksjonen eller funksjonene TIME, MINUTT og SEKUND.

Kolonne1Kolonne2FormelBeskrivelse
09/06/2007 10:3510/06/2007 15:30=HELTALL((Kolonne2-Kolonne1)*24)Totalt antall timer mellom to tidspunkt (28)
09/06/2007 10:3510/06/2007 15:30=HELTALL((Kolonne2-Kolonne1)*1440)Totalt antall minutter mellom to tidspunkt (1735)
09/06/2007 10:3510/06/2007 15:30=HELTALL((Kolonne2-Kolonne1)*86400)Totalt antall sekunder mellom to tidspunkt (104100)
09/06/2007 10:3510/06/2007 15:30=TIME(Kolonne2-Kolonne1)Timer mellom to tidspunkt hvor differansen ikke overskrider 24. (4)
09/06/2007 10:3510/06/2007 15:30=MINUTT(Kolonne2-Kolonne1)Minutter mellom to tidspunkt hvor differansen ikke overskrider 60. (55)
09/06/2007 10:3510/06/2007 15:30=SEKUND(Kolonne2-Kolonne1)Sekunder mellom to tidspunkt hvor differansen ikke overskrider 60. (0)

VisKonvertere tidspunkt

Hvis du vil konvertere timer fra standard tidsformat til et desimaltall, bruker du HELTALL-funksjonen.
Kolonne1FormelBeskrivelse
10:35=(Kolonne1-HELTALL(Kolonne1))*24Antall timer siden 12:00 (10.583333)
12:15=(Kolonne1-HELTALL(Kolonne1))*24Antall timer siden 12:00 (12.25)

Hvis du vil konvertere timer fra desimaltall til standard tidsformatet (timer:minutter:sekunder), bruker du divisjonsoperatoren og TEKST-funksjonen.

Kolonne1FormelBeskrivelse
10:5833=TEKST(Kolonne1/24; "h:mm")Timer siden 12:00 (10:35)
12:25=TEKST(Kolonne1/24; "h:mm")Timer siden 12:00 (12:15)

VisSette inn julianske datoer

Uttrykket "Juliansk dato" brukes noen ganger for å referer til et datoformat som er en kombinasjon av gjeldende år og antall dager siden begynnelsen av året. 1. januar 2007 representeres for eksempel som 2007001, og 31. desember 2007 representeres som 2003356.

Den finnes også en juliansk dato som ofte brukes innen astronomien, som er et serielt datosystem som starter 1. januar 4713 f.kr.

 Obs!   Dette formatet er ikke basert på den julianske kalenderen.

Hvis du vil konvertere en dato til en juliansk dato, bruker du funksjonene TEKST og DATOVERDI.

Kolonne1FormelBeskrivelse
23/6/2007=TEKST(Kolonne1;"yy")&TEKST((Kolonne1-DATOVERDI("1/1/"& TEKST(Kolonne1;"yy"))+1);"000")Dato i "juliansk" format, med et tosifret år (07174)
23/6/2007=TEKST(Kolonne1;"yyyy")&TEKST((Kolonne1-DATOVERDI("1/1/"&TEKST(Kolonne1;"yy"))+1);"000")Dato i "juliansk" format, med et firesifret år (2007174)

Hvis du skal konvertere en dato til en juliansk dato brukt i astronomien, bruker du konstanten 2415018.50.

Denne formelen fungerer bare for datoer etter 1/3/1901 og hvis du bruker 1900-datosystemet.

Kolonne1FormelBeskrivelse
23/6/2007=Kolonne1+2415018.50Dato i "juliansk" format, brukt i astronomien (2454274.50)

VisVise datoer som ukedagen

Hvis du vil konvertere datoer til teksten for dagen i uken, bruker du funksjonene TEKST og UKEDAG.
Kolonne1FormelBeskrivelse
19-feb-2007=TEKST(UKEDAG(Kolonne1); "dddd")Beregner dagen i uken for datoen og returnerer hele navnet på dagen (mandag)
3-jan-2008=TEKST(UKEDAG(Kolonne1); "ddd")Beregner dagen i uken for datoen og returnerer det forkortede navnet på dagen (tor)

Matematiske formler

VisAddere tall

Hvis du skal legge sammen tall i to eller flere kolonner i en rad, bruker du addisjonsoperatoren eller SUMMER-funksjonen.

Kolonne1 Kolonne2 Kolonne3 Formel Beskrivelse
6 5 4 =Kolonne1+Kolonne2+Kolonne3 Adderer (legger sammen) verdiene i de tre første kolonnene (15)
6 5 4 =SUMMER(Kolonne1;Kolonne2;Kolonne3) Adderer verdiene i de tre første kolonnene (15)
6 5 4 =SUMMER(HVIS(Kolonne1>Kolonne2; Kolonne1-Kolonne2; 10); Kolonne3) Hvis Kolonne1 er større enn Kolonne2, adderer du differansen til Kolonne3. Ellers adderer du 10 til Kolonne3. (5)

VisSubtrahere tall

Bruk subtraksjonsoperatoren (-) til denne oppgaven.
Kolonne1 Kolonne2 Kolonne3FormelBeskrivelse
150009000-8000=Kolonne1-Kolonne2Subtraherer (trekker fra) 9000 fra 15000 (6000)
150009000-8000=SUMMER(Kolonne1; Kolonne2; Kolonne3)Legger sammen tall i de første tre kolonnene, inkludert negative verdier (16000)

VisBeregner forskjellen mellom to tall som en prosentandel

Bruk operatorene for subtraksjon (-) og divisjon (/), og ABS-funksjonen.
Kolonne1Kolonne2FormelBeskrivelse
23422500=(Kolonne2-Kolonne1)/ABS(Kolonne1)Prosentvis endring (6,75% eller 0,06746)

VisMultiplisere tall

Bruk multiplikasjonsoperatoren (*) eller PRODUKT-funksjonen til denne oppgaven.
Kolonne1 Kolonne2 FormelBeskrivelse
52=Kolonne1*Kolonne2Multipliserer tallene i de første to kolonnene (10)
52=PRODUKT(Kolonne1; Kolonne2)Multipliserer tallene i de første to kolonnene (10)
52=PRODUKT(Kolonne1;Kolonne2;2)Multipliserer tallene i de første to kolonnene og tallet 2 (20)

VisDividere tall

Bruk divisjonsoperatoren (/) til denne oppgaven.

Kolonne1 Kolonne2 Formel Beskrivelse
15000 12 =Kolonne1/Kolonne2 Dividerer 15000 med 12 (1250)
15000 12 =(Kolonne1+10000)/Kolonne2 Adderer 15000 og 9000, og dividerer deretter totalen med 12 (2000)

VisBeregne gjennomsnittsverdien for tall

Gjennomsnittsverdien kalles også middelverdi. Hvis du skal beregne gjennomsnittet for tall i to eller flere kolonner i en rad, bruker du GJENNOMSNITT-funksjonen.

Kolonne1 Kolonne2 Kolonne3 Formel Beskrivelse
6 5 4 =GJENNOMSNITT(Kolonne1; Kolonne2;Kolonne3) Gjennomsnittet av tallene i de tre første kolonnene (5)
6 5 4 =GJENNOMSNITT(HVIS(Kolonne1>Kolonne2; Kolonne1-Kolonne2; 10); Kolonne3) Hvis Kolonne1 er større enn Kolonne2, beregnes gjennomsnittet mellom forskjellen og Kolonne3. Ellers beregnes gjennomsnittet mellom verdien 10 og Kolonne3. (2,5)

VisBeregne medianen for tall

Medianen er verdien i midten av en ordnet rekke med tall. Bruk MEDIAN-funksjonen til å beregne medianen i en gruppe med tall.
A B CDEFFormelBeskrivelse
10 792704=MEDIAN(A, B, C, D, E, F)Medianen for tallene i de 6 første kolonnene (8)

VisBeregne det minste eller største tallet i en rekkefølge

Du kan beregne det minste eller største tallet i to eller flere kolonner i en rad, ved å bruke funksjonene MIN og STØRST.
Kolonne1 Kolonne2 Kolonne3FormelBeskrivelse
10 79=MIN(Kolonne1; Kolonne2; Kolonne3)Det minste tallet (7)
1079=STØRST(Kolonne1; Kolonne2; Kolonne3)Det største tallet (10)

VisTelle verdier

Hvis du vil telle verdier, bruker du ANTALL-funksjonen.
Kolonne1 Kolonne2 Kolonne3FormelBeskrivelse
Eple12/12/2007=ANTALL(Kolonne1; Kolonne2; Kolonne3)Teller hvor mange kolonner som inneholder numeriske verdier, inkludert dato- og klokkeslettverdier. Utelater tekst- og null-verdier. (1)
$12#DIV/0!1,01=ANTALL(Kolonne1; Kolonne2; Kolonne3)Teller antall kolonner som inneholder numeriske verdier, men utelater feil og logiske verdier (2)

VisØke eller minske et tall med en prosentandel

Bruk prosentoperatoren (%) til denne oppgaven.
Kolonne1 Kolonne2 FormelBeskrivelse
233%=Kolonne1*(1+5%)Øker tallet i Kolonne1 med 5% (24,15)
233%=Kolonne1*(1+Kolonne2)Øker tallet i Kolonne1 med prosentverdien i Kolonne2: 3% (23,69)
233%=Kolonne1*(1-Kolonne2)Minsker tallet i Kolonne1 med prosentverdien i Kolonne2: 3% (22,31)

VisOpphøye et tall i en potens

Bruk eksponentieringsoperatoren (^) eller OPPHØYD.I-funksjonen til denne oppgaven.
Kolonne1 Kolonne2 FormelBeskrivelse
52=Kolonne1^Kolonne2Beregner 5 i andre potens (25)
53=OPPHØYD.I(Kolonne1; Kolonne2)Beregner 5 i tredje potens (125)

VisAvrunde et tall

Hvis du vil avrunde et tall, bruker du funksjonene AVRUND.OPP, AVRUND.TIL.ODDETALL og AVRUND.TIL.PARTALL.

Kolonne1 Formel Beskrivelse
20,3 =AVRUND.OPP(Kolonne1;0) Avrunder 20,3 opp til nærmeste heltall (21)
-5,9 =AVRUND.OPP(Kolonne1;0) Avrunder -5,9 oppover (-6)
12,5493 =AVRUND.OPP(Kolonne1;2) Avrunder 12,5493 opp til nærmeste hundredel, to desimalplasser (12,55)
20,3 =AVRUND.TIL.PARTALL(Kolonne1) Avrunder 20,3 oppover til nærmeste partall (22)
20,3 =AVRUND.TIL.ODDETALL(Kolonne1) Avrunder 20,3 oppover til nærmeste oddetall (21)

Hvis du vil avrunde et tall nedover, bruker du AVRUND.NED-funksjonen.

Kolonne1 Formel Beskrivelse
20,3 =AVRUND.NED(Kolonne1;0) Avrunder 20,3 ned til nærmeste heltall (20)
-5,9 =AVRUND.NED(Kolonne1;0) Avrunder -5,9 nedover (-5)
12,5493 =AVRUND.NED(Kolonne1;2) Avrunder 12,5493 ned til nærmeste hundredel, to desimalplasser (12,54)

Hvis du vil runde av et tall til nærmeste brøk, bruker du AVRUND-funksjonen.

Kolonne1 Formel Beskrivelse
20,3 =AVRUND(Kolonne1;0) Avrunder 20,3 nedover fordi brøkdelen er mindre enn ,5 (20)
5,9 =AVRUND(Kolonne1;0) Avrunder 5,9 oppover fordi brøkdelen er større enn ,5 (6)
-5,9 =AVRUND(Kolonne1;0) Avrunder -5,9 oppover fordi brøkdelen er større enn ,5 (-6)
1,25 =AVRUND(Kolonne1; 1) Avrunder tallet opp til nærmeste tidel (én desimal). Fordi delen som skal avrundes er 0,05 eller større, rundes tallet oppover (resultat: 1,3)
30,452 =AVRUND(Kolonne1; 2) Avrunder tallet opp til nærmeste hundredel (to desimaler). Fordi delen som skal avrundes, 0,002, er mindre enn 0,0005, rundes tallet nedover (resultat: 30,45)

Hvis du skal avrunde et tall til et signifikant siffer over 0, bruker du funksjonene AVRUND, AVRUND.OPP, AVRUND.NED, HELTALL og LENGDE.

Kolonne1 Formel Beskrivelse
5492820 =AVRUND(Kolonne1;3-LENGDE(HELTALL(Kolonne1))) Avrunder tallet til 3 signifikante sifre (5490000)
22230 =AVRUND.NED(Kolonne1;3-LENGDE(HELTALL(Kolonne1))) Avrunder det nederste tallet nedover til 3 signifikante sifre (22200)
5492820 =AVRUND.OPP(Kolonne1; 5-LENGDE(HELTALL(Kolonne1))) Avrunder det øverste tallet nedover til 5 signifikante sifre (5492900)

Tekstformler

VisEndre til store og små bokstaver

Bruk funksjonene STORE, SMÅ eller STOR.FORBOKSTAV til denne oppgaven.
Kolonne1FormelBeskrivelse
nina Davidsen=STORE(Kolonne1)Endrer teksten til store bokstaver (NINA DAVIDSEN)
nina Davidsen=SMÅ(Kolonne1)Endrer teksten til små bokstaver (nina davidsen)
nina Davidsen=STOR.FORBOKSTAV(Kolonne1)Gir ordene stor forbokstav (Nina Davidsen)

VisKombinere for- og etternavn

Bruk ampersand-operatoren (&) eller KJEDE.SAMMEN-funksjonen til denne oppgaven.
Kolonne1Kolonne2FormelBeskrivelse
NinaFransen=Kolonne1&Kolonne2Kombinerer de to strengene (NinaFransen)
NinaFransen=Kolonne1&" "&Kolonne2Kombinerer de to strengene atskilt med et mellomrom (Nina Fransen)
NinaFransen=Kolonne2&","&Kolonne1Kombinerer de to strengene atskilt med et komma (Fransen,Nina)
Nina Fransen=KJEDE.SAMMEN(Kolonne2; ","; Kolonne1)Kombinerer de to strengene atskilt med et komma (Fransen, Nina)

VisKombinere tekst og tall fra forskjellige kolonner

Bruk funksjonene KJEDE.SAMMEN og TEKST samt ampersand-operatoren (&) til denne oppgaven.
Kolonne1Kolonne2FormelBeskrivelse
Bottolfsen28=Kolonne1&" solgte "&Kolonne2&" enheter."Kombinerer innholdet ovenfor i et uttrykk (Bottolfsen solgte 28 enheter)
Larsen40%=Kolonne1&" solgte "&TEKST(Kolonne2;"0%")&" av totalt salg."Kombinerer innholdet ovenfor i et uttrykk (Larsen solgte 40% av totalt salgsvolum).

 Obs!   TEKST-funksjonen føyer til den formaterte verdien i Kolonne2 i stedet for den underliggende verdien ,som er ,4.

Bottolfsen28=KJEDE.SAMMEN(Kolonne1;" solgte";Kolonne2;" enheter.")Kombinerer innholdet ovenfor i et uttrykk (Bottolfsen solgte 28 enheter)

VisKombinere tekst med dato eller klokkeslett

Bruk TEKST-funksjonen og ampersand-operatoren (&) til denne oppgaven.
Kolonne1Kolonne2FormelBeskrivelse
Fakturadato5-jun-2007="Kontodato: "&TEKST(Kolonne2; "d-mmm-yyyy")Kombinerer tekst med en dato (Kontodato: 5-jun-2007)
Fakturadato5-jun-2007=Kolonne1&" "&TEKST(Kolonne2; "mmm-dd-yyyy")Kombinerer tekst og dato fra forskjellige kolonner til én kolonne (Fakturadato jun-05-2007)

VisSammenligne kolonneinnhold

Hvis du vil sammenligne en kolonne med en annen kolonne eller en liste med verdier, bruker du funksjonene EKSAKT og ELLER.
Kolonne1Kolonne2FormelBeskrivelse
BD122BD123=EKSAKT(Kolonne1;Kolonne2) Sammenligner innhold i de to første kolonnene (Nei)
BD122BD123=EKSAKT(Kolonne1; "BD122")Sammenligner innholdet i Kolonne1 med strengen "BD122" (Ja)
BD122BD123=ELLER(EKSAKT("BD121"; Kolonne1; Kolonne2)Sammenligner strengen "BD121" med innholdet i de to første kolonnene (Nei)

VisKontrollerer om en kolonneverdi eller deler av den samsvarer med en bestemt tekst

Hvis du vil kontrollere om en kolonneverdi eller en del av den, samsvarer med spesifikk tekst, bruker du funksjonene HVIS, FINN, SØK og ERTALL.

Kolonne1 Formel Beskrivelse
Davidsen =HVIS(Kolonne1="Davidsen"; "OK"; "Ikke OK") Kontrollerer om Kolonne1 er Davidsen (OK)
Davidsen =HVIS(ERTALL(FINN("v";Kolonne1)); "OK"; "Ikke OK") Kontrollerer om Kolonne1 inneholder bokstaven v (OK)
BD123 =ERTALL(FINN("BD";Kolonne1)) Kontrollerer om Kolonne1 inneholder BD (Ja)

VisTelle ikke-tomme kolonner

Bruk ANTALLA-funksjonen til denne oppgaven.
Kolonne1Kolonne2Kolonne3FormelBeskrivelse
Salg19=ANTALLA(Kolonne1; Kolonne2) Teller antall ikke-tomme kolonner (2)
Salg19=ANTALLA(Kolonne1; Kolonne2; Kolonne3)Teller antall ikke-tomme kolonner (2)

VisFjerne tegn fra tekst

Bruk funksjonene LENGDE, VENSTRE og HØYRE til denne oppgaven.
Kolonne1FormelBeskrivelse
Vitamin A=VENSTRE(Kolonne1;LENGDE(Kolonne1)-2)Returnerer de 7 (9-2) tegnene lengst mot venstre (Vitamin)
Vitamin B1=HØYRE(Kolonne1; LENGDE(Kolonne1)-8)Returnerer de 2 (10-8) tegnene lengst mot høyre(B1)

VisFjerne mellomrom fra begynnelsen og slutten av en kolonne

Bruk TRIMME-funksjonen til denne oppgaven.
Kolonne1FormelBeskrivelse
  Hallo der!=TRIMME(Kolonne1)Fjerner mellomrommene fra begynnelsen og slutten (Hallo der!)

VisGjenta et tegn i en kolonne

Bruk GJENTA-funksjonen til denne oppgaven.
FormelBeskrivelse
=GJENTA(".";3)Gjentar et punktum 3 ganger (...)
=GJENTA("-";10)Gjentar en strek 10 ganger (----------)

Andre formler

VisSkjule feilverdier i kolonner

Hvis du vil vise en strek, #I/T eller IT i stedet for en feilverdi, bruker du ERFEIL-funksjonen.
Kolonne1 Kolonne2 FormelBeskrivelse
100=Kolonne1/Kolonne2Fører til en feil (#DIV/0)
100=HVIS(ERFEIL(Kolonne1/Kolonne2);"IT";Kolonne1/Kolonne2)Returnerer IT når verdien er en feil
100=HVIS(ERFEIL(Kolonne1/Kolonne2);"-";Kolonne1/Kolonne2)Returnerer en strek når verdien er en feil
previous page start next page