Download

Downloads a file from the Internet.

Download(URL, FileName)

Download("http://ahkscript.org/download/index.htm", A_ScriptDir "\ahkscript.htm")

Download, http://ahkscript.org/download/index.htm, %A_ScriptDir%\ahkscript.htm

Parameters

URL

URL of the file to download. For example, http://someorg.org might retrieve the welcome page for that organization.

Filename

Download to a file: Specify the name of the file to be created locally, which is assumed to be in %A_WorkingDir% if an absolute path isn't specified. Any existing file will be overwritten by the new file.

Download to a variable: See the example below. For alternative methods, see the following forum topic: www.autohotkey.com/forum/topic10466.html

ErrorLevel

ErrorLevel is set to 1 if there was a problem or 0 otherwise.

Remarks

The download might appear to succeed even when the remote file doesn't exist. This is because many web servers send an error page instead of the missing file. This error page is what will be saved in place of Filename.

Firewalls or the presence of multiple network adapters may cause this function to fail. Also, some websites may block such downloads.

Caching: By default, the URL is retrieved directly from the remote server (that is, never from Internet Explorer's cache). To permit caching, precede the URL with *0 followed by a space; for example: *0 http://someorg.org. The zero following the asterisk may be replaced by any valid dwFlags number; for details, search www.microsoft.com for InternetOpenUrl.

Proxies: If a proxy server has been configured in Microsoft Internet Explorer's settings, it will be used.

FTP and Gopher URLS are also supported. For example:

Download, ftp://example.com/home/My File.zip, C:\My Folder\My File.zip  ; Log in anonymously.
Download, ftp://user:[email protected]:21/home/My File.zip, C:\My Folder\My File.zip  ; Log in as a specific user.
Download, ftp://user:[email protected]/My Directory, C:\Dir Listing.html  ; Gets a directory listing in HTML format.

Related

FileRead, FileCopy

Examples

Download, http://autohotkey.com/download/2.0/version.txt, C:\AutoHotkey Latest Version.txt
Download, http://someorg.org/archive.zip, C:\SomeOrg's Archive.zip

; Example: Download text to a variable:
whr := ComObjCreate("WinHttp.WinHttpRequest.5.1")
whr.Open("GET", "http://autohotkey.com/download/2.0/version.txt")
whr.Send()
; Using 'true' above and the call below allows the script to remain responsive.
whr.WaitForResponse()
version := whr.ResponseText
MsgBox % version

; Example: Make an asynchronous HTTP request.

req := ComObjCreate("Msxml2.XMLHTTP")
; Open a request with async enabled.
req.open("GET", "https://autohotkey.com/download/2.0/version.txt", true)
; Set our callback function (v1.1.17+).
req.onreadystatechange := Func("Ready")
; Send the request.  Ready() will be called when it's complete.
req.send()
/*
; If you're going to wait, there's no need for onreadystatechange.
; Setting async=true and waiting like this allows the script to remain
; responsive while the download is taking place, whereas async=false
; will make the script unresponsive.
while req.readyState != 4
    sleep 100
*/
#Persistent

Ready() {
    global req
    if (req.readyState != 4)  ; Not done yet.
        return
    if (req.status == 200 || req.status == 304) ; OK.
        MsgBox % "Latest AutoHotkey version: " req.responseText
    else
        MsgBox("Status " req.status,, 16)
    ExitApp
}