Item Method

Returns a border in a range or selection.

expression.Item(Index)

expression    Required. An expression that returns a Borders object.

Index   Required WdBorderType. The border to be returned.

Returns a dialog in Microsoft Word.

expression.Item(Index)

expression    Required. An expression that returns a Dialogs object.

Index   Required WdWordDialog. A constant that specifies the dialog.

Returns an Editor object that represents a specific user or a group of users who have been given permission to edit a portion of a document.

expression.Item(Index)

expression    Required. An expression that returns an Editors collection.

Index    Required Variant. Can be either a String that represents the user's e-mail alias (if in the same domain), an e-mail address, or a WdEditorType constant that represents a group of users.

Returns a header or footer in a range or selection.

expression.Item(Index)

expression    Required. An expression that returns a HeadersFooters object.

Index   Required WdHeaderFooterIndex. A constant that specifies the header or footer in the selection.

Returns the type of list (bulleted, numbered or outline) from the list template gallery.

expression.Item(Index)

expression    Required. An expression that returns a ListGalleries object.

Index   Required WdListGalleryType. A constant that specifies the type of list.

Returns a specified mapped data field.

expression.Item(Index)

expression    Required. An expression that returns a MappedDataFields object.

Index   Required WdMappedDataFields. The specified mapped data field.

Returns a single story of a range or selection as a Range object.

expression.Item(Index)

expression    Required. An expression that returns a StoryRanges object.

Index   Required WdStoryType. The specified story type.

Returns the specified task pane as a TaskPane object.

expression.Item(Index)

expression    Required. An expression that returns a TaskPanes object.

Index   Required WdTaskPanes. The specified task pane.

Returns the specified Zoom object.

expression.Item(Index)

expression    Required. An expression that returns a Zooms object.

Index   Required WdViewType. The specified zoom type.

Returns an individual object in a collection.

expression.Item(Index)

expression    Required. An expression that returns one of the objects in the above list.

Index   Required Variant or Long. The individual object to be returned.

For the following objects, Index can be a Variant indicating the ordinal position or a string representing the name of the individual object.

For the following objects, Index can be a Long indicating the ordinal position of the individual object.

This example selects the bookmark named "temp" in the active document.

Sub BookmarkItem()
    If ActiveDocument.Bookmarks.Exists("temp") = True Then
        ActiveDocument.Bookmarks.Item("temp").Select
    End If
End Sub

This example inserts a double border above the first paragraph in the active document.

Sub BorderItem()
    ActiveDocument.Paragraphs(1).Borders.Item(wdBorderTop) _
        .LineStyle = wdLineStyleDouble
End Sub

This example displays the Page Setup dialog.

Sub DialogItem()
    Application.Dialogs.Item(wdDialogFileDocumentLayout).Display
End Sub

This example displays the name of the first document in the Documents collection.

Sub DocumentItem()
    If Documents.Count >= 1 Then
        MsgBox Documents.Item(1).Name
    End If
End Sub

This example creates and formats a first page header in the active document.

Sub HeadFootItem()
    ActiveDocument.PageSetup.DifferentFirstPageHeaderFooter = True
    With ActiveDocument.Sections(1).Headers _
            .Item(wdHeaderFooterFirstPage).Range
        .InsertBefore "Sales Report"
        With .Font
            .Bold = True
            .Size = "15"
            .Color = wdColorBlue
        End With
        .Paragraphs.Alignment = wdAlignParagraphCenter
    End With
End Sub

This example clears all the items from the drop-down form field named "Colors" and then adds two color names. The Item method is used to display the first color in the drop-down form field.

Sub ListEntryItem()
    Dim d As DropDown
    Set d = ActiveDocument.FormFields.Add _
        (Range:=Selection.Range, _
        Type:=wdFieldFormDropDown).DropDown
    With d.ListEntries
        .Add Name:="Black"
        .Add Name:="Green"
    End With
    MsgBox d.ListEntries.Item(1).Name
End Sub