Ahora que ha obtenido la ubicación y la anchura del camino, puede dibujar su contorno. Añada el siguiente código bajo la subrutina gpuser:
' Dibujo del contorno del camino
Private Sub drawout()
Dim points(0 To 9) As Double
Dim pline As AcadLWPolyline
Dim varRet As Variant
varRet = ThisDrawing.Utility.PolarPoint( _
sp, angm90, hwidth)
points(0) = varRet(0)
points(1) = varRet(1)
points(8) = varRet(0)
points(9) = varRet(1)
varRet = ThisDrawing.Utility.PolarPoint( _
varRet, pangle, plength)
points(2) = varRet(0)
points(3) = varRet(1)
varRet = ThisDrawing.Utility.PolarPoint( _
varRet, angp90, totalwidth)
points(4) = varRet(0)
points(5) = varRet(1)
varRet = ThisDrawing.Utility.PolarPoint( _
varRet, pangle + dtr(180), plength)
points(6) = varRet(0)
points(7) = varRet(1)
Set pline = ThisDrawing.ModelSpace. _
AddLightWeightPolyline(points)
End Sub
Esta subrutina dibuja el contorno del camino utilizando el método AddLightweightPolyline. Este método requiere un parámetro: una matriz de puntos que genere la polilínea. Debe hallar todos los puntos que forman el objeto de polilínea y colocarlos en una matriz en el orden en que deben dibujarse. Para esta polilínea, los puntos necesarios son los vértices del camino.
Para hallar los vértices del camino, utilice el método PolarPoint. Este método encuentra un punto que está a un ángulo y una distancia determinados desde un punto base. Comience por el punto inicial (sp) y encuentre el primer vértice del camino trabajando en dirección contraria a las agujas del reloj. Este vértice estará a una distancia equivalente a la mitad de la anchura del camino (hwidth) y a -90 grados del ángulo del camino. Puesto que desea dibujar un rectángulo cerrado para el camino, ese punto se convierte en el primer y último punto de la matriz. Por lo tanto, las coordenadas X e Y obtenidas con el método PolarPoint se desplazan a la primera y a la última posición de la matriz de puntos.
Los restantes vértices del camino se hallan de la misma forma utilizando la longitud y la anchura del camino (plength y width), y el ángulo del camino. Cada vez que se invoca el método PolarPoint, las coordenadas obtenidas (varRet) se copian en la matriz de puntos.
Una vez identificados los vértices en la matriz de puntos, se invoca el método AddLightweightPolyline. Observe que este método es invocado desde el objeto ModelSpace. Si ejecutara esta macro, vería que la polilínea todavía no es visible en AutoCAD. La polilínea no será visible hasta que actualice la visualización, cosa que hará más tarde.