El reflejo de objetos crea una copia que es la imagen reflejada de un objeto con respecto a un eje o línea de simetría. Se pueden reflejar todos los objetos de dibujo.
Para reflejar un objeto, utilice el método Mirror. Este método requiere la entrada de dos coordenadas. Las dos coordenadas especificadas se convierten en puntos finales de la línea de simetría alrededor de la cual se refleja el objeto de base. En 3D, esta línea orienta un plano de simetría perpendicular al plano XY del SCP que contiene un eje de simetría especificado.
A diferencia del comando de simetría de AutoCAD, este método sitúa en el dibujo la imagen reflejada y mantiene el objeto original. Si desea eliminar el objeto original, utilice el método Erase.
Para controlar las propiedades de simetría de objetos de texto, utilice la variable de sistema MIRRTEXT. El valor por defecto de MIRRTEXT es activada (1), con el que la simetría de los objetos de texto se obtiene como la de los demás objetos. Cuando MIRRTEXT está desactivada (0), no se generan imágenes simétricas de texto. Utilice los métodos GetVariable y SetVariable para consultar y establecer el parámetro MIRRTEXT.
Puede obtener una imagen simétrica de un objeto de ventana gráfica en espacio papel, aunque ello no afecta a la vista de los objetos en el espacio modelo ni a los objetos de dicho espacio.
Para obtener información acerca del reflejo de objetos, véase “Copia, desfase y reflejo de objetos” en el Manual del usuario.
Reflexión de una polilínea con respecto a un eje
Este ejemplo crea una polilínea optimizada y la refleja con respecto a un eje de simetría. La nueva polilínea es de color azul.
Sub Ch4_MirrorPolyline()
' Create the polyline
Dim plineObj As AcadLWPolyline
Dim points(0 To 11) As Double
points(0) = 1: points(1) = 1
points(2) = 1: points(3) = 2
points(4) = 2: points(5) = 2
points(6) = 3: points(7) = 2
points(8) = 4: points(9) = 4
points(10) = 4: points(11) = 1
Set plineObj = ThisDrawing.ModelSpace. _
AddLightWeightPolyline(points)
plineObj.Closed = True
ZoomAll
' Define the mirror axis
Dim point1(0 To 2) As Double
Dim point2(0 To 2) As Double
point1(0) = 0: point1(1) = 4.25: point1(2) = 0
point2(0) = 4: point2(1) = 4.25: point2(2) = 0
' Mirror the polyline
Dim mirrorObj As AcadLWPolyline
Set mirrorObj = plineObj.Mirror(point1, point2)
Dim col As New AcadAcCmColor
Call col.SetRGB(125, 175, 235)
mirrorObj.TrueColor = col
ZoomAll
End Sub