Exportación e importación de parámetros de capa guardados

AutoCAD ActiveX

 
Exportación e importación de parámetros de capa guardados
 
 
 

Se pueden exportar e importar parámetros de capa guardados para utilizarlos en otros dibujos. Con el método Export del objeto LayerStateManager, los parámetros de capa se guardan en un archivo; con el método Import, se importan a un dibujo.

NotaLa importación de parámetros de capa no implica su restitución; es necesario utilizar el método Restore para que las capas del dibujo adquieran los parámetros importados.

El método Export admite dos parámetros. El primer parámetro consiste en una cadena identificativa de los parámetros de capa que se deseen exportar. El segundo parámetro es el nombre del archivo al que se deseen exportar. Si no se indica una ruta, el archivo se guarda en el directorio de instalación de AutoCAD. Si ya existe un archivo con el nombre especificado, el nuevo nombre sustituye al anterior. Al guardar los archivos, utilice la extensión .las; esta extensión permite a AutoCAD reconocer los archivos de parámetros de capa exportados.

El método Import acepta un parámetro: una cadena que señale el nombre del archivo que contiene los parámetros de capa que se desea importar.

Durante la importación de parámetros de capa, puede producirse una condición de error si las propiedades a las que refieren los parámetros guardados no están disponibles en el dibujo destino de la importación. La importación termina, no obstante, y se utilizan las propiedades por defecto. Por ejemplo, cuando en una capa exportada se establece un tipo de línea que no está cargado en el dibujo destino de la importación, se produce una condición de error y el tipo de línea por defecto del dibujo queda reemplazado. El código que se escriba debe tener en cuenta esta condición de error y continuar con el proceso si se produce.

Si el archivo importado define parámetros de capas que no existen en el dibujo actual, se crean dichas capas. Cuando se utiliza el método Restore, las propiedades que se especificaron al guardar los parámetros se asignan a las capas nuevas; todas las demás propiedades de las capas nuevas adquieren los parámetros establecidos por defecto.

Exportación de parámetros de capa guardados

El siguiente código exporta los parámetros de capa guardados a un archivo denominado Colortype.las.

Sub Ch4_ExportLayerSettings()
    Dim oLSM As AcadLayerStateManager
    Set oLSM = ThisDrawing.Application. _
       GetInterfaceObject("AutoCAD.AcadLayerStateManager.17")
    oLSM.SetDatabase ThisDrawing.Database
    oLSM.Export "ColorLinetype", "c:\my documents\ColorLType.las"
End Sub

Importación de parámetros de capa guardados

El siguiente código importa los parámetros de capa guardados desde un archivo denominado Colortype.las.

Sub Ch4_ImportLayerSettings()
    Dim oLSM As AcadLayerStateManager
    Set oLSM = ThisDrawing.Application. _
       GetInterfaceObject("AutoCAD.AcadLayerStateManager.17")
    oLSM.SetDatabase ThisDrawing.Database
      
    ' If the drawing you're importing to does not contain
    ' all the linetypes referenced in the saved settings,
    ' an error is returned. The import is completed, though,
    ' and the default linetype is used.
    On Error Resume Next
    oLSM.Import "c:\my documents\ColorLType.las"
    If Err.Number = -2145386359 Then
       ' Error indicates a linetype is not defined
       MsgBox ("One or more linetypes specified in the imported " + _
              "settings is not defined in your drawing")
    End If
    On Error GoTo 0
      
End Sub