Si desea utilizar un dibujo de AutoCAD en otra aplicación, puede convertirlo a un formato específico por medio del método Export. Este método permite exportar los dibujos de AutoCAD al formato WMF, SAT, EPS, DXF o BMP. El método Export requiere tres valores de entrada: el nombre del archivo que se creará, la extensión del nuevo archivo y el conjunto de selección de objetos para exportar.
Cuando realice una exportación a formatos WMF, SAT o BMP, debe proporcionar un conjunto de selección que no esté vacío. El conjunto de selección designa los objetos del dibujo que se desea exportar. Si no se precisa un conjunto de selección no se exporta nada, y el resultado es un error interceptable de argumento no válido.
Cuando se exporta a los formatos EPS o DXF, Export no considera, aunque lo requiere, el argumento del conjunto de selección. Se exporta automáticamente todo el dibujo.
Para exportar un dibujo como archivo DXF y volverlo a importar
En este ejemplo se crea un círculo en el dibujo actual. Después se exporta el dibujo a un archivo llamado DXFExprt.DXF. A continuación, se abre un dibujo nuevo y se importa el archivo. Tenga presente que a Export se le proporciona como argumento un conjunto de selección vacío. Aunque el método Export omite la información del conjunto de selección al exportar un archivo DXF, produciría un error si no se incluyera el argumento.
Sub Ch3_ImportingAndExporting()
' Create the circle for visual representation
Dim circleObj As AcadCircle
Dim centerPt(0 To 2) As Double
Dim radius As Double
centerPt(0) = 2: centerPt(1) = 2: centerPt(2) = 0
radius = 1
Set circleObj = ThisDrawing.ModelSpace.AddCircle _
(centerPt, radius)
ThisDrawing.Application.ZoomAll
' Create an empty selection set
Dim sset As AcadSelectionSet
Set sset = ThisDrawing.SelectionSets.Add("NEWSSET")
'Export the current drawing to a DXF file in the
' AutoCAD temporary file directory
Dim tempPath As String
Dim exportFile As String
Const dxfname As String = "DXFExprt"
tempPath = _
ThisDrawing.Application.preferences.Files.TempFilePath
exportFile = tempPath & dxfname
ThisDrawing.Export exportFile, "DXF", sset
' Delete the empty selection set
ThisDrawing.SelectionSets.Item("NEWSSET").Delete
' Open a new drawing
ThisDrawing.Application.Documents.Add "acad.dwt"
' Define the import
Dim importFile As String
Dim insertPoint(0 To 2) As Double
Dim scalefactor As Double
importFile = tempPath & dxfname & ".dxf"
insertPoint(0) = 0: insertPoint(1) = 0: insertPoint(2) = 0
scalefactor = 2#
' Import the file
ThisDrawing.Import importFile, insertPoint, scalefactor
ThisDrawing.Application.ZoomAll
End Sub