Edición de patrones de sombreado

AutoCAD ActiveX

 
Edición de patrones de sombreado
 
 
 

Puede modificar el ángulo y el espaciado de un patrón de sombreado existente o sustituirlo por un relleno sólido o por uno de los patrones predefinidos provistos por AutoCAD. La opción Patrón del cuadro de diálogo Sombreado permite ver una lista de los patrones. Para reducir el tamaño del archivo, el sombreado se define en el dibujo como un solo objeto gráfico.

Utilice los siguientes métodos y propiedades para modificar los patrones de sombreado:

PatternAngle

Determina el ángulo del patrón de sombreado.

PatternDouble

Indica si el sombreado definido por el usuario es un sombreado doble.

PatternName

Especifica el nombre del patrón de sombreado (no cambia el tipo del patrón).

PatternScale

Determina la escala de los patrones de sombreado.

PatternSpace

Especifica el espaciado del patrón de sombreado definido por el usuario.

SetPattern

Define el nombre y el tipo del patrón de sombreado.

Modificación del intervalo del patrón de un sombreado

Este ejemplo crea un sombreado. Después añade dos al espaciado del patrón actual del sombreado.

Sub Ch4_ChangeHatchPatternSpace()
    Dim hatchObj As AcadHatch
    Dim patternName As String
    Dim PatternType As Long
    Dim bAssociativity As Boolean
      
    ' Define the hatch
    patternName = "ANSI31"
    PatternType = 0
    bAssociativity = True
      
    ' Create the associative Hatch object
    Set hatchObj = ThisDrawing.ModelSpace. _
        AddHatch(PatternType, patternName, bAssociativity)
      
    ' Create the outer loop for the hatch.
    Dim outerLoop(0 To 0) As AcadEntity
    Dim center(0 To 2) As Double
    Dim radius As Double
    center(0) = 5
    center(1) = 3
    center(2) = 0
    radius = 3
    Set outerLoop(0) = ThisDrawing.ModelSpace. _
                                AddCircle(center, radius)
    hatchObj.AppendOuterLoop (outerLoop)
    hatchObj.Evaluate
      
    ' Change the spacing of the hatch pattern by
    ' adding 2 to the current spacing
    hatchObj.patternSpace = hatchObj.patternSpace + 2
    hatchObj.Evaluate
    ThisDrawing.Regen True
End Sub