Propiedad FilterIndex

Devuelve o establece un valor Long que indica el filtro de archivos predeterminado de un cuadro de diálogo de archivos. El filtro predeterminado determina qué tipos de archivos se muestran al abrir por primera vez el cuadro de diálogo de archivos. Lectura/Escritura.

expresión   Requerida. Expresión que devuelve uno de los objetos de la lista Aplicar a.

Comentarios

Si intenta establecer esta propiedad a un número superior que el de filtros, se seleccionará el último filtro disponible.

Ejemplo

El ejemplo siguiente muestra un cuadro de diálogo Selector de archivos mediante el objeto File Dialog, así como cada archivo seleccionado en un cuadro de mensaje. Este ejemplo muestra también cómo agregar un filtro de archivos nuevo y hacer que sea el filtro predeterminado.

Sub Main()

    'Declare a variable as a FileDialog object.
    Dim fd As FileDialog

    'Create a FileDialog object as a File Picker dialog box.
    Set fd = Application.FileDialog(msoFileDialogFilePicker)

    'Declare a variable to contain the path
    'of each selected item. Even though the path is a String,
    'the variable must be a Variant because For Each...Next
    'routines only work with Variants and Objects.
    Dim vrtSelectedItem As Variant

    'Use a With...End With block to reference the FileDialog object.
    With fd

        'Add a filter that includes GIF and JPEG images and make it the second item in the list.
        .Filters.Add "Images", "*.gif; *.jpg; *.jpeg", 2

        'Sets the initial file filter to number 2.
        .FilterIndex = 2

        'Use the Show method to display the File Picker dialog box and return the user's action.
        'If the user presses the action button...
        If .Show = -1 Then

            'Step through each string in the FileDialogSelectedItems collection.
            For Each vrtSelectedItem In .SelectedItems

                'vrtSelectedItem is a String that contains the path of each selected item.
                'You can use any file I/O functions that you want to work with this path.
                'This example simply displays the path in a message box.
                MsgBox "Selected item's path: " & vrtSelectedItem

            Next vrtSelectedItem
        'If the user presses Cancel...
        Else
        End If
    End With

    'Set the object variable to Nothing.
    Set fd = Nothing

End Sub