Objeto OfficeDataSourceObject

OfficeDataSourceObject Varios objetos

Representa el origen de datos de combinación de correspondencia de una operación de combinación de correspondencia.

Utilizar el objeto OfficeDataSourceObject

Para trabajar con el objeto OfficeDataSourceObject, dimensione una variable como un objeto OfficeDataSourceObject. A continuación puede trabajar con los diferentes métodos y propiedades asociados con el objeto. Utilice el método SetSortOrder para especificar cómo se clasificarán los registros de un origen de datos. El ejemplo siguiente clasifica primero el origen de datos según el código postal en orden descendente, a continuación, según el apellido y el nombre de pila en orden ascendente.

Sub SetDataSortOrder()
    Dim appOffice As OfficeDataSourceObject

    Set appOffice = Application.OfficeDataSourceObject
    appOffice.Open bstrConnect:="DRIVER=SQL Server;SERVER=ServerName;" & _
        "UID=user;PWD=;DATABASE=Northwind", bstrTable:="Employees"

    appOffice.SetSortOrder SortField1:="ZipCode", _
        SortAscending1:=False, SortField2:="LastName", _
        SortField3:="FirstName"
End Sub

Utilice las propiedades Column, Comparison, CompareTo y Conjunction para devolver o establecer el criterio de consulta de origen de datos. El ejemplo siguiente cambia un filtro existente para quitar de la combinación de correspondencia todos los registros cuyo campo Región no sea "WA".

Sub SetQueryCriterion()
    Dim appOffice As Office.OfficeDataSourceObject
    Dim intItem As Integer

    appOffice.Open bstrConnect:="DRIVER=SQL Server;SERVER=ServerName;" & _
        "UID=user;PWD=;DATABASE=Northwind", bstrTable:="Employees"

    With appOffice.Filters
        For intItem = 1 To .Count
            With .Item(intItem)
                If .Column = "Region" Then
                    .Comparison = msoFilterComparisonNotEqual
                    .CompareTo = "WA"
                    If .Conjunction = "Or" Then .Conjunction = "And"
                End If
            End With
        Next intItem
    End With
End Sub