Objeto ODSOFilter

Representa el filtro que se aplicará a un origen de datos de combinación de correspondencia adjunto. El objeto ODSOFilter es un miembro del objeto ODSOFilters.

Utilizar el objeto ODSOFilter

Cada filtro es una línea de una cadena de consulta. Utilice las propiedades Column, Comparison, CompareTo y Conjunction para devolver o establecer el criterio de consulta del origen de datos. El ejemplo siguiente cambia un filtro existente para quitar de la combinación de correspondencia todos los registros cuyo campo Región no sea "WA".

Sub SetQueryCriterion()
    Dim appOffice As Office.OfficeDataSourceObject
    Dim intItem As Integer

    Set appOffice = Application.OfficeDataSourceObject
    appOffice.Open bstrConnect:="DRIVER=SQL Server;SERVER=ServerName;" & _
        "UID=user;PWD=;DATABASE=Northwind", bstrTable:="Employees"

    With appOffice.Filters
        For intItem = 1 To .Count
            With .Item(intItem)
                If .Column = "Region" Then
                    .Comparison = msoFilterComparisonNotEqual
                    .CompareTo = "WA"
                    If .Conjunction = "Or" Then .Conjunction = "And"
                End If
            End With
        Next intItem
    End With
End Sub

Utilice el método Add del objeto ODSOFilters para agregar un criterio de filtro nuevo a una consulta. Este ejemplo agrega una línea nueva a la cadena de consulta y, a continuación, aplica el filtro combinado al origen de datos.

Sub SetQueryCriterion()
    Dim appOffice As OfficeDataSourceObject

    Set appOffice = Application.OfficeDataSourceObject
    appOffice.Open bstrConnect:="DRIVER=SQL Server;SERVER=ServerName;" & _
        "UID=user;PWD=;DATABASE=Northwind", bstrTable:="Employees"

    With appOffice.Filters
        .Add Column:="Region", _
            Comparison:=msoFilterComparisonIsBlank, _
            Conjunction:=msoFilterConjunctionAnd
        .ApplyFilter
    End With
End Sub