Propiedad ButtonName

Establece o devuelve un valor String que representa el texto que se muestra en el botón de acción de un cuadro de diálogo de archivos. De forma predeterminada, esta propiedad está establecida en el texto estándar para el tipo de cuadro de diálogo de archivos. Por ejemplo, en el caso del cuadro de diálogo Abrir, la propiedad está establecida a "Abrir" de forma predeterminada. Lectura/Escritura.

expresión   Requerida. Expresión que devuelve uno de los objetos de la lista Aplicar a.

Ejemplo

El ejemplo siguiente muestra un cuadro de diálogo Selector de archivos mediante el objeto File Dialog, así como cada archivo seleccionado en un cuadro de mensaje.

Sub Main()

    'Declare a variable as a FileDialog object.
    Dim fd As FileDialog

    'Create a FileDialog object as a File Picker dialog box.
    Set fd = Application.FileDialog(msoFileDialogFilePicker)

    'Declare a variable to contain the path
    'of each selected item. Even though the path is a String,
    'the variable must be a Variant because For Each...Next
    'routines only work with Variants and Objects.
    Dim vrtSelectedItem As Variant

    'Use a With...End With block to reference the FileDialog object.
    With fd

        'Change the text on the action button.
        .ButtonName = "Archive"

        'Use the Show method to display the File Picker dialog box and return the user's action.
        'If the user presses the action button...
        If .Show = -1 Then

            'Step through each String in the FileDialogSelectedItems collection.
            For Each vrtSelectedItem In .SelectedItems

                'vrtSelectedItem is a String that contains the path of each selected item.
                'You can use any file I/O functions that you want to work with this path.
                'This example simply displays the path in a message box.
                MsgBox "Selected item's path: " & vrtSelectedItem

            Next vrtSelectedItem
        'If the user presses Cancel...
        Else
        End If
    End With

    'Set the object variable to Nothing.
    Set fd = Nothing

End Sub