Objeto ODSOFilters

OfficeDataSourceObject ODSOFilters
ODSOFilter

Representa todos los filtros para aplicar al origen de datos adjunto a la publicación de combinación de correspondencia. El objeto ODSOFilters consta de objetos ODSOFilter.

Utilizar el objeto ODSOFilters

Utilice el método Add del objeto ODSOFilters para agregar un criterio de filtro nuevo a una consulta. Este ejemplo agrega una línea nueva a la cadena de consulta y, a continuación, aplica el filtro combinado al origen de datos.

Sub SetQueryCriterion()
    Dim appOffice As OfficeDataSourceObject

    Set appOffice = Application.OfficeDataSourceObject
    appOffice.Open bstrConnect:="DRIVER=SQL Server;SERVER=ServerName;" & _
        "UID=user;PWD=;DATABASE=Northwind", bstrTable:="Employees"

    With appOffice.Filters
        .Add Column:="Region", _
            Comparison:=msoFilterComparisonIsBlank, _
            Conjunction:=msoFilterConjunctionAnd
        .ApplyFilter
    End With
End Sub

Utilice el método Item para tener acceso a un criterio de filtro concreto. Este ejemplo recorre todo el criterio de filtro y si encuentra uno con un valor de "Región", lo cambia para quitar de la combinación de correspondencia todos los registros que no sean "WA".

Sub SetQueryCriterion()
    Dim appOffice As Office.OfficeDataSourceObject
    Dim intItem As Integer

    Set appOffice = Application.OfficeDataSourceObject
    appOffice.Open bstrConnect:="DRIVER=SQL Server;SERVER=ServerName;" & _
        "UID=user;PWD=;DATABASE=Northwind", bstrTable:="Employees"

    With appOffice.Filters
        For intItem = 1 To .Count
            With .Item(intItem)
                If .Column = "Region" Then
                    .Comparison = msoFilterComparisonNotEqual
                    .CompareTo = "WA"
                    If .Conjunction = "Or" Then .Conjunction = "And"
                End If
            End With
        Next intItem
    End With
End Sub