用其他应用程序的对象进行编程
用其他应用程序的对象进行编程
从 VBA 访问 Windows API
以编程方式启动应用程序，会占用计算机的内存，所以使用完毕后应该退出应用程序，以释放系统资源。
虽然每个对象模型各不相同，但是大部分都可以使用 Application 对象的 Quit 方法来完全关闭应用程序。例如，使用上节的变量声明，以下代码行将使 Excel 退出：
ExcelAppObj.Application.Quit
注意破坏或超出对象变量的作用域，不一定会导致应用程序终止。一定要使用适当的方法退出应用程序，以确保正确清除内存。
以下子例程在当前图形中查找所有的块引用，然后查找附着到这些块引用的属性，并将它们列在 Excel 电子表格中。要运行本样例，请按以下步骤执行：
- 打开包含块引用的图形，这些块引用带有属性。（样例图形 sample/activeX/attrib.dwg 包含这样的块引用。）
- 使用 AutoCAD VBAIDE 命令打开 VBA IDE。
- 在 VBA IDE 中依次使用“工具”
“引用”菜单选项，以选择“Microsoft Excel 8.0 对象模型”。 - 将这个子例程复制到 VBA 的“代码”窗口中并运行它。
Sub Ch12_Extract()
Dim Excel As Excel.Application
Dim ExcelSheet As Object
Dim ExcelWorkbook As Object
Dim RowNum As Integer
Dim Header As Boolean
Dim elem As AcadEntity
Dim Array1 As Variant
Dim Count As Integer
' 启动 Excel。
Set Excel = New Excel.Application
' 创建新的工作簿并查找活动电子表格。
Set ExcelWorkbook = Excel.Workbooks.Add
Set ExcelSheet = Excel.ActiveSheet
ExcelWorkbook.SaveAs "Attribute.xls"
RowNum = 1
Header = False
' 遍历模型空间，查找
' 所有的块引用。
For Each elem In ThisDrawing.ModelSpace
With elem
' 找到块引用时，
' 检查其属性
If StrComp(.EntityName, "AcDbBlockReference", 1) _
= 0 Then
If .HasAttributes Then
' 获取属性
Array1 = .GetAttributes
' 将属性的标记字符串
' 复制到 Excel
For Count = LBound(Array1) To UBound(Array1)
If Header = False Then
If StrComp(Array1(Count).EntityName, _
"AcDbAttribute", 1) = 0 Then
ExcelSheet.Cells(RowNum, _
Count + 1).value = _
Array1(Count).TagString
End If
End If
Next Count
RowNum = RowNum + 1
For Count = LBound(Array1) To UBound(Array1)
ExcelSheet.Cells(RowNum, Count + 1).value _
= Array1(Count).textString
Next Count
Header = True
End If
End If
End With
Next elem
Excel.Application.Quit
End Sub