処理シーケンス実行のサンプル・ファンクション
これは、用意されているTUT_01_P1処理シーケンスを実行するサンプル・ファンクションです。このサンプルで、DXP1FN1ファンクションを呼び出して、LANSAアプリケーションから処理シーケンスを実行する際の重要な事項をすべて確認できます。
* --------------------------------------------------------
* このファンクションは準備されたTUT_01_P1処理シーケンスを実行し、
* 必要なパラメータ値を提供します。
* --------------------------------------------------------
function options(*direct)
* --------------------------------------------------------
* 処理シーケンスパラメータの作業リスト
* --------------------------------------------------------
def_list name(#dxparms) fields(#dxapnm #dxpvsq #dxpvvl) type(*working) entrys(100)
* --------------------------------------------------------
* 処理シーケンスIDを設定し、交換
* ([監査情報タブ]に表示されている内部識別子を使用)
* --------------------------------------------------------
#dxp1ii := '2D123D3124F84042AFB1E931838DA90E'
exchange fields(#dxp1ii)
* --------------------------------------------------------
* 実行に指定されたパラメータを提供
* --------------------------------------------------------
#dxpvsq := 1
#dxapnm := 'YOURINITIALS'
#dxpvvl := 'LA'
add_entry to_list(#dxparms)
#dxapnm := 'YOURMESSAGE'
#dxpvvl := 'This run was initiated by my LANSA application'
add_entry to_list(#dxparms)
#dxapnm := 'YOURNAME'
#dxpvvl := 'LANSA Application'
add_entry to_list(#dxparms)
* --------------------------------------------------------
* 処理シーケンスの実行
* --------------------------------------------------------
call process(*direct) function(DXP1FN1) pass_lst(#dxparms)
* --------------------------------------------------------
* 結果の判定
* --------------------------------------------------------
if (#dxexrc = 'OK')
message msgtxt('Processing sequence run was successful')
else
message msgtxt('Processing sequence run ended abnormally')
endif
* --------------------------------------------------------
* 終了
* --------------------------------------------------------
return