Click Event

Occurs when the user clicks a CommandBarButton object.

The syntax for the Click event includes the two arguments described in the following table.

Argument	Description
Ctrl	Required CommandBarButton. Denotes the CommandBarButton control that initiated the event.
CancelDefault	Required Boolean. False if the default behavior associated with the CommandBarButton control occurs, unless it’s canceled by another process or add-in.

Remarks

The Click event is recognized by the CommandBarButton object. To return the Click event for a particular CommandBarButton control, use the WithEvents keyword to declare a variable, and then set the variable to the control.

Example

The following example creates a new command bar button on the File menu of the host application that enables the user to save a workbook as a comma-separated value file. (This example works in all applications, but the context of saving as CSV is applicable to Microsoft Excel.)

Private HostApp As Object

Sub createAndSynch()
    Dim iIndex As Integer
    Dim iCount As Integer
    Dim fBtnExists As Boolean
    
    Dim obCmdBtn As Object
    Dim btnSaveAsCSVHandler as new Class1
    
    On Error GoTo errHandler
       
    Set HostApp = Application
    
    Dim barHelp As Office.CommandBar
    Set barHelp = Application.CommandBars("File")
    fBtnExists = False
    iCount = barHelp.Controls.Count
    For iIndex = 1 To iCount
        If barHelp.Controls(iIndex).Caption = "Save As CSV (Comma Delimited)" Then fBtnExists = True
    
    Next
    Dim btnSaveAsCSV As Office.CommandBarButton
    If fBtnExists Then
        Set btnSaveAsCSV = barHelp.Controls("Save As CSV (Comma Delimited)")
    Else
        Set btnSaveAsCSV = barHelp.Controls.Add(msoControlButton)
        btnSaveAsCSV.Caption = "Save As CSV (Comma Delimited)"
    End If
    
    btnSaveAsCSV.Tag = "btn1"
    btnSaveAsCSVHandler.SyncButton btnSaveAsCSV
    Exit Sub
    
errHandler:
    ' Insert error handling code here
End Sub