Command and CommandText Properties Example (VB)

Command and CommandText Properties Example (VB)

The following code demonstrates how to use the Command property to update the text of a procedure.

' BeginProcedureTextVB
Sub Main()
    On Error GoTo ProcedureTextError
    
    Dim cnn As New ADODB.Connection
    Dim cat As New ADOX.Catalog
    Dim cmd As New ADODB.Command
    
    ' Open the Connection
    cnn.Open "Provider='Microsoft.Jet.OLEDB.4.0';" & _
        "Data Source='c:\Program Files\Microsoft Office\" & _
        "Office\Samples\Northwind.mdb';"
    
    ' Open the catalog
    Set cat.ActiveConnection = cnn
    
    ' Get the Command
    Set cmd = cat.Procedures("CustomerById").Command

    ' Update the CommandText
    cmd.CommandText = "Select CustomerId, CompanyName, ContactName " & _
        "From Customers " & _
        "Where CustomerId = [CustId]"
    
    ' Update the Procedure
    Set cat.Procedures("CustomerById").Command = cmd
    
    'Clean up
    cnn.Close
    Set cat = Nothing
    Set cmd = Nothing
    Set cnn = Nothing
    Exit Sub
    
ProcedureTextError:
    Set cat = Nothing
    Set cmd = Nothing
    
    If Not cnn Is Nothing Then
        If cnn.State = adStateOpen Then cnn.Close
    End If
    Set cnn = Nothing
    
    If Err <> 0 Then
        MsgBox Err.Source & "-->" & Err.Description, , "Error"
    End If
End Sub
' EndProcedureTextVB

See Also

ActiveConnection Property | Catalog Object | Command Property | Procedure Object | Procedures Collection