RegRead

从注册表读取值.

RegRead, OutputVar, RootKey\SubKey [, ValueName]  ; v1.1.21+
RegRead, OutputVar, RootKey, SubKey [, ValueName]

参数

OutputVar

用来存储获取值的变量名. 如果无法获取, 则变量被置空且 ErrorLevel 被设置为 1.

RootKey

必须为 HKEY_LOCAL_MACHINE, HKEY_USERS, HKEY_CURRENT_USER, HKEY_CLASSES_ROOT 或 HKEY_CURRENT_CONFIG 的其中一个 (或者它们的缩写, 例如 HKLM). 要访问远程注册表, 请在前面加上计算机名和冒号 (或 v1.1.21+ 用正斜线 /), 例如: \\workstation01:HKEY_LOCAL_MACHINE

SubKey

子键名 (例如 Software\SomeApplication).

RootKey\SubKey [v1.1.21+]

如果在 RootKey 后面紧随一个反斜杠 (\), RootKey 和 SubKey 将被合并成一个变量.

ValueName

要获取的值名. 如果省略, 则获取 Subkey 的默认值, 这是在注册表中值名显示为 "(默认)" 的值. 如果没有默认值 (即注册表中显示 "数值未设置"), 则 OutputVar 被置空且 ErrorLevel 被设置为 1.

ErrorLevel

[v1.1.04+] 此命令失败时会抛出异常. 想了解更多信息, 请参阅 运行时错误.

如果遇到问题 (例如不存在的键或值名) 则 ErrorLevel 被设置为 1, 否则为 0.

A_LastError 被设置为操作系统 GetLastError() 函数返回的结果.

备注

目前只支持下列这些值类型: REG_SZ, REG_EXPAND_SZ, REG_MULTI_SZ, REG_DWORD 以及 REG_BINARY.

REG_DWORD 值总是被转换为正十进制数.

读取 REG_BINARY 键时, 获取的结果为十六进制字符的字符串. 例如, REG_BINARY 类型的值 01,a9,ff,77 的读取结果为字符串 01A9FF77.

读取 REG_MULTI_SZ 键时, 值的每个部分会以换行符结束 (`n). 如果值为空, 则 OutputVar 会被置空. 请参阅 FileSelectFile 中的示例了解如何从 OutputVar 中逐个提取单独的部分.

大于 64K 的 REG_BINARY 值只有在 v1.1.10.01 或更高版本中才能读取.

要获取和操作多个注册表键或值, 请考虑使用 注册表循环.

关于如何访问远程计算机注册表的详情, 请参阅 注册表循环 中的备注.

要在 32 位脚本中读写注册表 64 位部分的条目或进行相反的操作,请使用 SetRegView.

相关

RegDelete, RegWrite, 注册表循环, SetRegView, IniRead

示例

; 例子: 返回 Program Files 目录的路径.

;此行确保在64位系统上运行非64位脚本时也能正常返回64位的 Program Files 目录路径.
SetRegView 64  ; 需要 v1.1.08+

RegRead, OutputVar, HKEY_LOCAL_MACHINE, SOFTWARE\Microsoft\Windows\CurrentVersion, ProgramFilesDir
MsgBox, Program files are in: %OutputVar%

; 备用写法 (需要 v1.1.21+):
RegRead, OutputVar, HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion, ProgramFilesDir
MsgBox, Program files are in: %OutputVar%

; 另一种返回 Program Files 目录路径的方法:
EnvGet OutputVar, % A_Is64bitOS ? "ProgramW6432" : "ProgramFiles"
MsgBox, Program files are in: %OutputVar%

; 下面的例子获取注册表值的类型 (例如 REG_SZ 或 REG_DWORD).
MsgBox % RegKeyType("HKCU", "Environment", "TEMP")
return

RegKeyType(RootKey, SubKey, ValueName)  ; 此函数返回指定值的类型.
{
    Loop, %RootKey%, %SubKey%
        if (A_LoopRegName = ValueName)
            return A_LoopRegType
    return "Error"
}