debuginfo 1;

//デバッグ出力をONにする。
debuginfo 1;
debuginfo str(100);
debuginfo "debuginfoのテスト1";
//デバッグ出力をOFFにする。
debuginfo 0;
debuginfo "debuginfoのテスト2(出力されない)";
//デバッグ出力をONにする。
debuginfo 1;
debuginfo "debuginfoのテスト3";
endmacro;

//デバッグ出力をONにする。
debuginfo 1;

call DEBUGOUT "debuginfoのテスト1";
//デバッグ出力をOFFにする。
debuginfo 0;
call DEBUGOUT "debuginfoのテスト2(出力されない)";
//デバッグ出力をONにする。
debuginfo 1;
call DEBUGOUT "debuginfoのテスト3";
endmacro;

//デバッガ出力用サブルーチン
DEBUGOUT:
    $$debug_message = $$1;
    //デバッガのチェック1
    ##debugger1 = findwindowclass("HM_DebugMonitor");
    //デバッガのチェック2
    if(##debugger1 == 0)##debugger2 = findwindowclass("dbgviewClass");
    //両方見つからない場合は終了
    if(##debugger1 == 0 && ##debugger2 == 0) return;
    //秀丸エディタ・デバッグ出力モニターの場合は、最後に改行を追加
    if(##debugger1 != 0 && rightstr($$debug_message, 1) != "\x0a") $$debug_message = $$debug_message + "\x0a";
    //デバッガに出力
    debuginfo $$debug_message;
return;

---------------------------
秀丸エディタ
---------------------------
無題のまま保存されたファイルがあります。
読み込みますか？
---------------------------
はい(Y)   いいえ(N)   
---------------------------

//初期化処理
call DBOUT_INIT;
//実際に出力する
call DBOUT "デバッグ出力1!!:" + time + "\n";
newfile;
call DBOUT "デバッグ出力2!!:" + time + "\n";
settabgroup -1;
call DBOUT "デバッグ出力3!!:" + time + "\n";
endmacro;

//----------------------//
//  デバック出力
//----------------------//
DBOUT:
    if(#Debug_OutputFlg == 1 ){
        ##main = hidemaruhandle(0);
        ##focus = getfocus;
        if(#Debug_TabMode == 0 && ##main != #Debug_Hidemaru){
            //非タブモードの場合、ウィンドウ毎にアウトプット枠が存在するので、同じウィンドウに出力する。
            setactivehidemaru #Debug_Hidemaru;
        }else if(#Debug_TabMode == 1 && #Debug_TabGroup != tabgroup){
            //タブモードで、グループIDが初期化時と違っていたら、同じタブに出力する。
            setactivehidemaru getcurrenttab(false, #Debug_TabGroup);
        }
        debuginfo $$1;
        //元に戻す
        if(##main != hidemaruhandle(0)) setactivehidemaru ##main;
        if(getfocus != ##focus) setfocus ##focus;
    }
return;

//----------------------//
//  デバック初期化
//----------------------//
DBOUT_INIT:
    #Debug_TabMode  = tabmode;
    #Debug_TabGroup = tabgroup;
    #Debug_Hidemaru = hidemaruhandle(0);
    debuginfo 2;
    debuginfo "";
    //アウトプット枠をクリアする場合は有効にする。
    //ここから
    ##Debug_OutputPanel = loaddll("HmOutputPane.dll");
    if(##Debug_OutputPanel == 0){
        #Debug_OutputFlg = 0;
        return;
    }
    ##outputhandle = dllfunc(##Debug_OutputPanel, "GetWindowHandle", hidemaruhandle(0));
    ##ret = sendmessage(##outputhandle, 0x111, 1009, 0);//1009=クリア
    //ここまで
    #Debug_OutputFlg = 1;
return;

//初期化処理
call DBOUT_INIT;
call DBOUT "デバッグ出力1!!:" + time;
call DBOUT "デバッグ出力2!!:" + time;
endmacro;

//----------------------//
//  デバック出力ルーチン
//----------------------//
DBOUT:
    //ログ出力フラグがセットされていて、ハンドルが有効なら、ログ出力ファイルへ追加
    if(#Debug_OutputFlg == 1 && #Debug_OutputHandle > 0){
        //呼び出し元のハンドルとフォーカスを保存
        ##main = hidemaruhandle(0);
        ##focus = getfocus;
        //ログ出力ファイルへ切替
        if(##main != #Debug_OutputHandle) setactivehidemaru #Debug_OutputHandle;
        //出力カウンタ読み出しと更新
        $$cnt = getstaticvariable("debug_cnt",0);
        //ファイルの最後に移動して、ログを出力
        gofileend;
        insert $$1 + "\n";
        ##cnt = val($$cnt) + 1;
        //カウンタが10を超えたら保存して、カウンタリセット
        if(##cnt > 10){
            save;
            ##cnt = 0;
        }
        //カウンタ保存
        setstaticvariable "debug_cnt", str(##cnt), 0;
        //呼び出し元に戻る
        if(##main != #Debug_OutputHandle) setactivehidemaru ##main;
        if(getfocus != ##focus) setfocus ##focus;
    }
return;

//----------------------//
//  デバック初期化
//----------------------//
DBOUT_INIT:
    //呼び出し元のハンドルを保存
    ##main = hidemaruhandle(0);
    //tmpフォルダを取得
    $$debugfile = getenv("temp");
    if($$debugfile == "")$$debugfile = getenv("tmp");
    //tmpフォルダの取得に失敗した場合は終了
    if($$debugfile == ""){
        #Debug_OutputFlg = 0;
        return;
    }
    //ログ出力ファイル名を決める
    $$debugfile = $$debugfile + "\\Debug_OutPut.txt";
    //ログ出力ファイルを検索する
    #Debug_OutputHandle = findhidemaru($$debugfile);
    //自分自身は検索出来ないので、ファイル名をチェック
    if(#Debug_OutputHandle == -1){
        if(tolower($$debugfile) == filename) #Debug_OutputHandle = hidemaruhandle(0);
    }
    //それでも見つからない場合はログ出力ファイルを開く
    if(#Debug_OutputHandle == -1){
        openfile "/i \"" + $$debugfile + "\"";
        #Debug_OutputHandle = hidemaruhandle(0);
    }
    //ログ出力ファイルをアクティブな状態にして、変数を設定
    setactivehidemaru #Debug_OutputHandle;
    setstaticvariable "debug_cnt", "0", 0;
    
    //デバッグ内容をクリアする場合は有効にする。
    //selectall;delete;
    //ログ出力フラグをセット
    #Debug_OutputFlg = 1;
    setactivehidemaru ##main;
return;