SetLocale, fonction

Microsoft VBScript

Microsoft® Visual Basic® Scripting Edition SetLocale, fonction

Description

Définit les paramètres régionaux globaux et renvoie les paramètres régionaux précédents.

Syntaxe

SetLocale(lcid)
L'argument lcid peut correspondre à toute valeur 32 bits acceptable ou à une abréviation identifiant de manière unique une langue parlée sur un territoire géographique bien précis. Les valeurs reconnues figurent dans le tableau des ID de langue.

Notes

Si lcid est nulle, les paramètres régionaux sont définis de manière à correspondre à ceux en vigueur pour le système.

Les paramètres régionaux sont un ensemble d'informations indiquant les préférences d'un utilisateur quant à sa langue, son pays et ses conventions culturelles. Ils déterminent notamment la disposition des touches sur le clavier, l'ordre utilisé pour le tri alphabétique, ainsi que les formats à respecter pour les dates, les heures, les nombres et les devises.

L'exemple ci-dessous illustre l'utilisation de la fonction SetLocale. Pour utiliser ce code, collez l'exemple dans son intégralité entre les balises <BODY> d'une page HTML standard.
Entrer la date en format Anglais-GB : <input type="text" id="UKDate" size="20"><p>
Voici l'équivalent pour le format Anglais-US : <input type="text" id="USdate" size="20"><p>
<input type="button" value="Convert" id="button1"><p>
Entrer un prix au format allemand : &nbsp; <input type="text" id="GermanNumber" size="20">
<p>
Voici l'équivalent au format Anglais-GB : <input type="text" id="USNumber" size="20"><p>
<input type="button" value="Convert" id="button2"><p>

<script language="vbscript">
Dim currentLocale
' Get the current locale
currentLocale = GetLocale

Sub Button1_onclick
  Dim original
  original = SetLocale("en-gb")
  mydate = CDate(UKDate.value)
  ' Internet Explorer définit toujours les paramètres régionaux sur Anglais-US ; aussi utilisez
  ' la variable currentLocale pour les définir sur Anglais-US
  original = SetLocale(currentLocale)
  USDate.value = FormatDateTime(mydate,vbShortDate)
End Sub

Sub button2_onclick
  Dim original
  original = SetLocale("de")
  myvalue = CCur(GermanNumber.value)
  original = SetLocale("en-gb")
  USNumber.value = FormatCurrency(myvalue)
End Sub

</script> 

previous page start next page