SplashTextOn / SplashTextOff

Creates a customizable text popup window.

SplashTextOff
SplashTextOn , Width, Height, Title, Text

Parameters

Width

The width in pixels of the Window. Default 200. This parameter can be an expression.

Height

The height in pixels of the window (not including its title bar). Default 0 (i.e. just the title bar will be shown). This parameter can be an expression.

Title

The title of the window. Default empty (blank).

Text

The text of the window. Default empty (blank). If Text is long, it can be broken up into several shorter lines by means of a continuation section, which might improve readability and maintainability.

Remarks

To have more control over layout and font name/color/size, use the Progress command with the zh0 option, which omits the bar and displays only text. For example: Progress, zh0 fs18, Some 18-point text to display.

Use the SplashTextOff command to remove an existing splash window.

The splash window is "always on top", meaning that it stays above all other normal windows. To change this, use WinSet, AlwaysOnTop, Off, <insert title of splash window>. WinSet can also make the splash window transparent.

WinMove can be used to reposition and resize the SplashText window after it has been displayed with this command.

Unlike Progress, SplashImage, MsgBox, InputBox, FileSelectFile, and FileSelectFolder, only one SplashText window per script is possible.

If SplashTextOn is used while the splash window is already displayed, the window will be recreated with the new parameter values. However, rather than recreating the splash window every time you wish to change its title or text, better performance can be achieved by using the following, especially if the window needs to be changed frequently:

WinSetTitle, <insert title of splash window>, , NewTitle
ControlSetText, Static1, NewText, <insert title of splash window>

Related

Progress, SplashImage, ToolTip, MsgBox, InputBox, FileSelectFile, FileSelectFolder, WinMove, WinSet

Example

SplashTextOn, , , Displays only a title bar.
Sleep, 2000
SplashTextOn, 400, 300, Clipboard, The clipboard contains:`n%clipboard%
WinMove, Clipboard, , 0, 0  ; Move the splash window to the top left corner.
MsgBox, Press OK to dismiss the SplashText
SplashTextOff