Creación de secuencias de comandos para instalar programas
Uso de secuencias de comandos para implantar el programa
Uso de conmutadores e indicadores en las secuencias de comandos
La secuencia de comandos de ejemplo de esta sección instala el programa en una configuración típica. Para facilitar la copia de esta secuencia de comandos de ejemplo y sustituir la información personal, se utilizarán los mismos nombres para los elementos de variable. El nombre del archivo de registro dependerá del producto que se instale. Puede utilizar el nombre del archivo de registro en la secuencia de comandos o cambiarlo.
Prefijo del número de serie: 123
Número de serie: 12345678
Nombre: su nombre
Apellidos: sus apellidos
Organización: el nombre de su empresa
Una secuencia de comandos de ejemplo para una instalación silenciosa de este programa utiliza la sintaxis que se muestra en esta sección.
Instalación mediante secuencia de comandos para AutoCAD 2008
' Instalación mediante secuencia de comandos para AutoCAD 2008
con opciones explícitas
'
' Crear variables
dim x64bit
dim shell
dim productType
dim featuresToInstall
dim strADSKFirstName
dim strADSKLastName
dim strADSKOrganization
dim strADSKSercirity
dim strADSKSerialIsvalid
dim strADSKAccept
dim strADSKEula
dim strADSKReInstall
dim strADSKRemove
dim strADSKSNPrefix
dim strADSKSNNumber
dim strInstallLevel
dim strACADStandaloneNetworkType
dim strADSKLicenseServerType
dim strADSKLicenseType
dim strADSKServerFmtPath
dim strADSKServerPath
dim strADSKServerHostID
dim strADSKPath
dim strSourcePath
dim strAdditionalStuff
'
' Inicio de la secuencia de comandos
Set shell = CreateObject("WScript.Shell")
x64bit = false ' cambiar a true si se trata de AutoCAD 2008 x64
productType = "acad"
strInstallLevel=3 ' 5 instala todo 3 instala típica
'
' Información de nombre y organización
strADSKFirstName = "Nombre"
strADSKLastName = "Apellido"
strADSKOrganization = "Nombre de organización"
'
' Información de número de serie
strADSKSNPrefix = "123"
strADSKSNNumber = "12345678"
'
' Origen de la instalación (p. ej. D: se asume que es el soporte de instalación)
strSourcePath = "d:\"
'
' Destino de la instalación
strADSKPath = Shell.ExpandEnvironmentStrings("%ProgramFiles%") + "\AutoCAD 2008"
'
' Funciones a instalar
' ACS - Ejemplos de AutoCAD
' CADStandards - Normas de CAD
' Database - Base de datos (CONEXIONBD)
' DCS - Ejemplos de DesignCenter
' DigSig - Firmas digitales
' Dictionaries - Diccionarios
' DrawingEncryption - Cifrado de dibujos
' Express_Tools - Express Tools
' Fonts - Tipos de letra
' Impression - Barra de herramientas de Autodesk Impression (NO está en AutoCAD 2008 64 bits)
' Materials - Biblioteca de materiales
' Migrate - Migración de parámetros personalizados
' NFW - Taller de novedades
' PLM - Utilidad de licencia portátil
' RefMan - Administrador de referencias
' System_Files - Archivos de sistema necesarios (instalados por defecto en esta secuencia de comandos)
' TM - Mapas de texturas
' VBA - Visual Basic para aplicaciones
' VLS - Ejemplos de Visual LISP
' VLT - Aprendizajes de Visual LISP
'
' El ejemplo se muestra debajo - Tenga en cuenta la coma precedente
featuresToInstall = ",DigSig,TM,CADStandards,Database,Dictionaries,DrawingEncryption,Express_Tools,Fonts,NFW,Migrate,RefMan,Samples,ACS,DCS,VBA,Materials,PLM,VLS,VLT"
if not x64bit then
' Para añadir Autodesk Impression a la instalación
featuresToInstall = featuresToInstall & ",Impression"
strAdditionalStuff = "ACADSHOWIMPR=" & """" & "1" & """"
end if
'''''' Comentar la versión relevante de la instalación - La opción por defecto es Autónoma
' Para Autónoma
RunStandaloneInstall()
'
' Para Servidor de licencias de red único
'RunSingleLicenseServerInstall()
'
' Para Servidores de licencias de red redundantes
'RunRedundantLicenseServerInstall()
'
' Para Servidores de licencia de red distribuidos
'RunDistributedLicenseServerInstall()
'
' Fin de la secuencia de comandos
Wscript.quit()
'
Function RunStandaloneInstall
shell.run DefaultCommand(),2,1
end function
'
Function RunSingleLicenseServerInstall
' Actualizar con la información correcta para el servidor de licencias
strACADStandaloneNetworkType = "3"
strADSKLicenseServerType = "Licencia de servidor único"
strADSKLicenseType = "Licencia de red"
strADSKServerPath = "miServidorFlex"
' Dirección HOSTID o MAC
strADSKServerHOSTID = "001122334455"
'
' Consolidar los dos valores
strADSKServerPath = strADSKServerPath & " " & strADSKServerHOSTID
shell.run MakeCommand(),2,1
end function
'
Function RunRedundantLicenseServerInstall
' Actualizar con la información correcta para los servidores de licencias
strACADStandaloneNetworkType = "3"
strADSKLicenseServerType = "Licencia de servidor redundante"
strADSKLicenseType = "Licencia de red"
'
' El formato es NOMBREDESERVIDOR1 DIRMAC1 PUERTO1;NOMBREDESERVIDOR2 DIRMAC2 PUERTO2; NOMBREDESERVIDOR3 DIRMAC3 PUERTO3; - Sólo se permiten 3 servidores redundantes
strADSKServerPath = " miServidorFlex 001122334455 27005; miServidorFlex2 006622334455 27005;"
shell.run MakeCommand(),2,1
end function
'
Function RunDistributedLicenseServerInstall
' Actualizar con la información correcta para los servidores de licencias
strACADStandaloneNetworkType = "3"
strADSKLicenseServerType = "Licencia de servidor distribuido"
strADSKLicenseType = "Licencia de red"
'
' El formato es @NOMBREDESERVIDOR1;NOMBREDESERVIDOR2;NOMBREDESERVIDOR3;
strADSKServerPath = "@ miServidorFlex;@ miServidorFlex2;@ miServidorFlex;"
'
shell.run MakeCommand() & "ACAD_LICENSESERVER_DISTRIBUTED=1",2,1
end function
'
Function DefaultCommand
dim retString
' /q para instalación silenciosa ' /c [clave] modificar parámetros de la clave
retString = strSourcePath & "\setup.exe /t /q /c " & productType & ": "
retString = retString & "INSTALLDIR=" & """" & strADSKPath & """" & " "
retString = retString & "ACADSERIALPREFIX=" & strADSKSNPrefix & " "
retString = retString & "ACADSERIALNUMBER=" & strADSKSNNumber & " "
retString = retString & "ACADFIRSTNAME=" & """" & strADSKFirstName & """" & " "
retString = retString & "ACADLASTNAME=" & """" & strADSKLastName & """" & " "
retString = retString & "ACADORGANIZATION=" & """" & strADSKOrganization & """" & " "
retString = retString & "InstallLevel=" & strInstallLevel & " "
' retString = retString & "ADSK_LAUNCH_MODE=Standalone" & " "
if strInstallLevel = 3 then
retString = retString & "ADDLOCAL=" & """" & "System_Files" & featuresToInstall & """" & " "
end if
retString = retString & strAdditionalStuff ' Específicamente para la Barra de herramientas de Autodesk Impression
DefaultCommand = retString & " "
end function
'
Function MakeCommand
dim retString
retString = DefaultCommand() & " "
retString = retString & "ACADSTANDALONENETWORKTYPE=" & """" & strACADStandaloneNetworkType & """" & " "
retString = retString & "ACADLICENSESERVERTYPE=" & """" & strADSKLicenseServerType & """" & " "
retString = retString & "ACADLICENSETYPE=" & """" & strADSKLicenseType & """" & " "
retString = retString & "ACADSERVERPATH=" & """" & strADSKServerPath & """" & " "
MakeCommand = retString
end function